Страница 1 из 1

О командной строке

СообщениеДобавлено: 15 ноя 2011 15:36, Вт
UncleFather
Общий подход

Командные файлы – это текстовые файлы с расширением bat или cmd, строки которых представляют собой команды или имена исполняемых файлов. Когда вы запускаете на выполнение командный файл, то управление получает командный процессор операционной системы (часто называемый интерпретатором команд), который последовательно считывает и интерпретирует строки командного файла. Для Windows9X этим занимается command.com, для WinNT/2K/XP – cmd.exe. Строки командных файлов могут содержать команды самого процессора команд (FOR, GOTO, IF и т.п.) или имена исполняемых модулей (net.exe, regedit.exe, win.com и т.п.). В операционных системах WinNT/2K/XP можно получить краткую справку по составу команд с помощью командной строки:
Код: Выделить всё
HELP

или по конкретной команде:
Код: Выделить всё
HELP Имя команды

Чтобы открыть "справочник по командной строке" не в текстовом, а в более привычном в Windows оконном режиме (здесь команды и параметры описаны более подробно), нужно выполнить:
Код: Выделить всё
%windir%\hh.exe ms-its:%windir%\Help\ntcmds.chm::/ntcmds.ctm

Для выдачи текста справки не на экран, а в файл, можно воспользоваться перенаправлением вывода. При использовании командной строки, стандартным устройством ввода является клавиатура, а устройством вывода – дисплей, однако эти устройства можно переназначить с использованием символов перенаправления
Код: Выделить всё
<
- перенаправление ввода
Код: Выделить всё
>
- перенаправление вывода (или
Код: Выделить всё
>>
- перенаправление в существующий файл, когда выводимые данные дописываются в конец файла.)
Для вывода потока данных команды HELP в файл help.txt командная строка будет следующей:
Код: Выделить всё
HELP > help.txt

Для вывода справки по команде GOTO в файл goto.txt:
Код: Выделить всё
HELP GOTO > goto.txt



Использование переменных окружения.

В командных файлах можно, а зачастую, и нужно использовать переменные окружения – переменные, значения которых характеризуют среду, в которой выполняется команда или пакетный файл. Значения переменных окружения формируются при загрузке ОС и регистрации пользователя в системе, а также могут быть заданы с помощью команды SET , формат которой:
Код: Выделить всё
SET [переменная=[строка]]

где
переменная - Имя переменной среды.
строка - Строка символов, присваиваемая указанной переменной.

Например, командная строка
SET mynane=Vasya
добавит переменную myname, принимающую значение Vasya.
Можно получить значение переменной в программах и командных файлах, используя ее имя, заключенное в знаки процента (%). Например команда
Код: Выделить всё
ECHO time

выведет на экран слово time, а команда
Код: Выделить всё
ECHO %time%

выведет на экран значение переменной time, принимающей значение текущего времени.
А командная строка
Код: Выделить всё
SET PATH=C:\myprog;%path%

добавит в путь поиска исполняемых программ, описываемый значением переменной PATH каталог C:\myprog

Выполнение команды SET без параметров вызывают выдачу текущих значений переменных на экран, в виде:

NUMBER_OF_PROCESSORS=1 - количество процессоров
OS=Windows_NT- тип ОС
Path=E:\WINDOWS\system32;E:\WINDOWS;E:\Program Files\Far - путь поиска исполняемых файлов.
PATHEXT=.COM;.EXE;.BAT;.CMD;.VBS;.VBE;.JS;.JSE;.WSF;.WSH - расширения для исполняемых файлов.
PROCESSOR_ARCHITECTURE=x86 - архитектура процессора.
PROCESSOR_IDENTIFIER=x86 Family 6 Model 8 Stepping 1, AuthenticAMD - идентификатор процессора.
PROCESSOR_LEVEL=6 - уровень (номер модели) процессора.
PROCESSOR_REVISION=0801 - версия процессора.
ProgramFiles=E:\Program Files - путь к папке "Program Files"
PROMPT=$P$G - формат приглашения командной строки $P - путь для текущего каталога $G - знак ">".
SystemDrive=E: - буква системного диска.
SystemRoot=E:\WINDOWS - каталог ОС Windows.

Значение некоторых переменных по команде SET не выдаются. Это переменные, значения которых динамически изменяются :

%CD% - Принимает значение строки текущей директории.
%DATE% - Принимает значение текущей даты.
%TIME% - Принимает значение текущего времени.
%RANDOM% - Принимает значение случайного десятичного числа в диапазоне 1 -32767.
%ERRORLEVEL% - Принимает текущее значение кода завершения задачи ERRORLEVEL
%CMDEXTVERSION% - Принимает значение версии командного процессора CMD.EXE для расширенной обработки команд.
%CMDCMDLINE% - Принимает значение строки, которая вызвала командный процессор.

Для просмотра значения переменной можно использовать командную строку:
Код: Выделить всё
ECHO %переменная%



Входные параметры для командного файла.

Существует возможность передать командному файлу параметры командной строки и использовать их значения в операторах самого командного файла.
Код: Выделить всё
BAT-файл < параметр1 > , < параметр2 >, ... < параметрN >


В самом командном файле первый параметр будет доступен как переменная %1, второй - %2 и т.п. Имя самого командного файла доступно как переменная %0. Для примера создадим командный файл, задачей которого будет выдача на экран значений введенных параметров. Обычно для вывода текста используется команда
Код: Выделить всё
ECHO < текст >


Однако, если текст заменить на %1, - то будет выдан первый параметр, на %2 - второй и т.д.

Создаем файл parm.bat следующего содержания:
Код: Выделить всё
echo Первый параметр=%1
echo Второй параметр=%2
echo Третий параметр = %3


и запускаем его на выполнение следующей командой:
Код: Выделить всё
parm.bat FIRST second “two words”


После его выполнения вы поймете, как это работает и что параметры с пробелами, нужно заключать в двойные кавычки. Для того, чтобы обрабатываемые командным процессором строки не выдавались на экран, можно воспользоваться командой ECHO OFF, поместив ее в первую строку командного файла. Для того, чтобы строка командного файла игнорировалась командным процессором поместите в ее начало REM< пробел > . Таким образом можно помещать комментарии, зачастую нелишние в больших командных файлах:
Код: Выделить всё
rem ECHO OFF выключает режим вывода содержания строк командного файла на экран
REM будет выводиться только результат их выполнения.
ECHO OFF
echo Первый параметр=%1
echo Второй параметр=%2
echo Третий параметр = %3


Попробуйте ECHO OFF заменить на @ECHO OFF – результат говорит сам за себя. Строка, которая выключает режим вывода, перестала выдаваться на экран.


Переходы и метки.

В командных файлах можно использовать команды условного перехода, меняющие логику их работы в зависимости от выполнения определенных условий. Для иллюстрации приемов использования условных переходов создадим командный файл, целью которого будет присвоение заранее определенной буквы диска для съемных носителей, в качестве которых будут использоваться флэш-диски. Условия таковы – есть 2 флэш-диска, один из которых должен быть виден в проводнике как диск X: а второй – как диск Y: независимо от того, в какой порт USB они подключены. Будем считать, что реальные диски могут быть подключены как F: или G:

Опознавание дисков будем выполнять по наличию файла с определенным именем (лучше такой файл сделать скрытым в корневом каталоге и назвать его как-нибудь необычно):

Flashd1.let – на первом диске
Flashd2.let – на втором

Т.е. задача командного файла заключается в том, чтобы проверить наличие на сменных дисках F: и G: файлов Flashd1.let или Flashd2.let и, в зависимости от того, какой из них присутствует, присвоить диску букву X: или Y:
Для поиска файла на диске используем команду IF EXIST:
Код: Выделить всё
IF EXIST имя_файла команда

В качестве команды проще всего воспользоваться SUBST, сопоставляющей имя диска и каталог.
Код: Выделить всё
SUBST X: C:\
- создает виртуальный диск X:, содержимым которого будет корневой каталог диска C:
Создаем командный файл setXY.bat со следующими строками:
Код: Выделить всё
@ECHO OFF
IF EXIST G:\flashd1.let SUBST X: G:IF EXIST F:\flashd1.let SUBST X: F:IF EXIST G:\flashd2.let SUBST Y: G:IF EXIST F:\flashd2.let SUBST Y: F:\


После выполнения такого файла у вас появятся диски X: и Y: Но если такой файл выполнить повторно, команда SUBST выдаст сообщение об ошибке – ведь диски X: и Y: уже существуют.

Желательно обойти выполнение SUBST, если виртуальные диски X: и Y: уже созданы, (или удалять их, используя SUBST с параметром –d перед подключением ). Модифицируем командный файл с использованием GOTO - передачи управления строке пакетного файла по метке.
Код: Выделить всё
GOTO метка

Метка должна находиться в отдельной строке и начинаться с двоеточия. Сделаем изменения в нашем командном файле, чтобы не возникало сообщений об ошибке:
Код: Выделить всё
@ECHO OFF
REM если не существует X: - то перейдем на метку SETX
IF NOT EXIST X:\ GOTO SETX
REM если существует X: - перейдем на проверку наличия Y:
GOTO TESTY
:SETX
IF EXIST G:\flashd1.let SUBST X: G:IF EXIST F:\flashd1.let SUBST X: F::TESTY
REM если Y: существует – завершим командный файл.
IF EXIST Y:\ GOTO EXIT
IF EXIST G:\flashd2.let SUBST Y: G:IF EXIST F:\flashd2.let SUBST Y: F:REM выход из командного файла
:EXIT

Сообщение об ошибке SUBST исчезло. Признаки ошибок при выполнении команд можно отслеживать и в самом командном файле, анализируя переменную ERRORLEVEL, значение которой формируется при выполнении большинства программ. ERRORLEVEL равно 0, если программа завершилась без ошибок и 1 – при возникновении ошибки. Могут быть и другие значения, если они предусмотрены в выполняемой программе.

В качестве команды в строке командного файла можно использовать также командный файл. Причем, для передачи с возвратом обратно к точке выполнения вызывающего командного файла используется команда CALL . Создадим командный файл test.bat, следующего содержания:
Код: Выделить всё
@ECHO OFF
ECHO Вызов 1.bat
CALL 1.bat
ECHO Возврат

И файл 1.bat, содержащий команду PAUSE, приостанавливающую выполнение командного файла до нажатия любой клавиши.
Код: Выделить всё
@ECHO OFF
pause

При выполнении test.bat будет выдано на экран сообщение
Вызов 1.bat
и управление получит 1.bat с командой pause. После начатия клавиши на клавиатуре управление получит командная строка “ECHO Возврат.” и на экран будет выдано
Возврат


Если же в test.bat убрать CALL , то возврат из файла 1.bat выполняться не будет. Кстати, используя передачу управления командному файлу, можно организовать его зацикливание. Попробуйте добавить в конец файла test.bat строку:
Код: Выделить всё
CALL test.bat

Выйти из зацикливания командного файла можно по нажатию комбинации CTRL-Break. Возможно использование команды CALL для вызова процедуры внутри командного файла. В этом случае в качестве аргумента используется не имя внешнего файла, а метка:
Код: Выделить всё
....
call :proc1
....
:proc1
....
exit
....



Примеры

Создание файлов

В Windows нет специальной команды для создания файла, но без нее можно легко обойтись несколькими способами:

  1. Копирование с консоли в файл
    Код: Выделить всё
    COPY CON myfile.txt

    При выполнении этой команды данные с клавиатуры (устройство CON) будут заноситься в файл myfile.txt. Нажатие клавиши F6 или комбинации CTRL-Z завершит вывод.
  2. Перенаправление вывода
    Код: Выделить всё
    ECHO 1 > myfile.txt

    При выполнении этой команды будет создан файл myfile.txt, содержащий символ “1”
  3. Комбинация перенаправления ввода и вывода:
    Код: Выделить всё
    COPY CON > myfile.txt < xyz

    При выполнении этой команды, как и в первом случае, используется копирование с консоли в файл, но вместо данных с клавиатуры используется ввод с несуществующего устройства xyz. Система выдаст сообщение, о том, что такого устройства не существует, но пустой файл myfile.txt будет успешно создан.
  4. Совсем простой вариант - копирование с фиктивного устройства с именем nul в файл.
    Код: Выделить всё
    copy nul myfile.txt

Если вам часто приходится создавать пустые файлы, можно подготовить свой командный файл (например – newfile.bat или, что еще лучше, - nf.bat), а имя создаваемого файла передавать ему в качестве параметра при запуске.
Содержимое файла:
Код: Выделить всё
@ECHO OFF
copy nul %1


Поместите этот командный файл в системный каталог (C:\windows\system32 или любой другой, имеющийся в путях поиска, задаваемых PATH).
Командная строка:
Код: Выделить всё
newfile.bat myfile.txt

или
Код: Выделить всё
nf.bat myfile.txt

или
Код: Выделить всё
nf myfile.txt


Вот вам и команда nf для создания пустого файла в командной строке.


Присвоение съемному диску одной и той же буквы

Задача заключается в том, чтобы съемный USB диск (флэш диск) был доступен всегда под одной и той же буквой, независимо от того, на каком компьютере он используется и как он подключен. Для ее решения воспользуемся уже упоминаемой выше командой SUBST. Выберем для съемного диска желаемую букву, например - X. Имя диска, с которого был запущен командный файл доступно как переменная %~d0. Создаем командный файл следующего содержания:
Код: Выделить всё
@echo off
subst X: %~d0\

что означает - создать виртуальный диск X:, которому сопоставлен физический диск, откуда был выполнен запуск командного файла.
Дополнительное представление о подстановочных значениях переменной %0 можно получить из командного файла следующего содержания:
Код: Выделить всё
@echo off
ECHO ОБРАБАТЫВАЕТСЯ ФАЙЛ - %0
ECHO Дата/время создания/изменения командного файла - %~t0
ECHO Путь командного файла - "%~f0"
ECHO Диск командного файла - %~d0
ECHO Каталог командного файла - "%~p0"
ECHO Имя командного файла - %~n0
ECHO Расширение командного файла - %~x0
ECHO Короткое имя и расширение - %~s0
ECHO Атрибуты командного файла - %~a0
ECHO Размер командного файла - %~z0



Создание поколений архивов по датам и времени

Решим следующую задачу - нужно создать архив файлов, находящихся в каталоге C:\Program Files\FAR. Имя архивного файла должно состоять из текущего времени (часы.минуты.секунды - ЧЧ.ММ.СС.rar), и помещен он должен в новый каталог, имя которого должно состоять из текущей даты (день.месяц.год - ДД.ММ.ГГГГ). Для архивирования будем использовать архиватор RAR. Формат запуска для создания архива:
Код: Выделить всё
RAR a -r < путь и имя архива > < Путь и имя архивируемых данных >

a - команда создания архива.
-r - ключ, определяющий архивирование подкаталогов (т.к. в исходной папке есть подкаталоги).

Таким образом, для решения задачи нужно правильно создать имена и пути для RAR. Для чего воспользуемся следующими факторами:
  • В командных файлах можно получить доступ к текущей дате и текущему времени - переменные %DATE% и %TIME%
  • В командных файлах можно создавать временные переменные с помощью команды SET.
  • Значение временных переменных может быть сформировано на основе %DATE% и %TIME% путем пропуска и (или) замещения их частей с помощью все той же команды SET.

Дата, получаемая из переменной %DATE% при стандартных настройках региональных установок выглядит следующим образом:
Пн 21.01.2005
- День недели(2 символа)-Пробел-дата(10 символов)

Для примера, создадим каталог командой
Код: Выделить всё
MD < имя каталога >


Создаем в памяти временную переменную VDATE и присваем ей значение переменной окружения DATE, без первых 3-х символов - 20.01.2005:
Код: Выделить всё
set VDATE=%date:~3%

Создаем каталог на диске C:, имя которого = текущая дата из переменной VDATE:
Код: Выделить всё
MD C:\%VDATE%


После выполнения этой команды на диске C: будет создан каталог с именем 20.01.2005

Время, получаемое из переменной %TIME%:
14:30:59.93 - Часы, минуты, секунды, сотые доли секунды.
Сотые доли - это в имени файла архива, пожалуй, лишнее. Создаем временную переменную VTIME и присваиваем ей текущее время без последних 3-х символов
Код: Выделить всё
set VTIME=%time:~0,-3%


Теперь VTIME = 14:30:59, но знак " : " в имени файла использовать нельзя, поэтому заменим его на точку.
Код: Выделить всё
set VTIME=%VTIME::=.%


Переменная VTIME примет значение 14.30.59 Для имени файла сойдет.

Запустим архиватор:
Код: Выделить всё
rar a -r C:\%VDATE%\%VTIME%.rar "C:\Program files\far\*.*"


Теперь можно создать командный файл с содержимым:
Код: Выделить всё
set VDATE=%date:~3%
md c:\%VDATE%
set VTIME=%time:~0,-3%
set VTIME=%VTIME::=.%
rar a -r C:\%VDATE%\%VTIME%.rar "C:\Program files\far\*.*"


Такой командный файл можно выполнять через автозагрузку, или как часть скрипта, при входе пользователя в домен, либо с помощью планировщика в заданное время, и у вас всегда будут в наличии упорядоченные по времени архивы критических данных.


Создание архивов с использованием переменных профиля пользователя

Этот командный файл создает архивы содержимого папки "Мои Документы" пользователей Win2K/XP, размещая их в каталоги
C:\ARHIV\Мои документы\Имя пользователя\Дата\время

Используются переменные USERPROFILE, USERNAME, WINDIR, поэтому в WIN9X этот командный файл работать не будет. (Хотя, при желании вы можете вставить в autoexec.bat команды для установки значений этих переменных и использовать его в однопользовательском варианте практически без изменений). Содержимое командного файла снабжено комментариями и не должно вызывать особых затруднений, если вы разобрались с предыдущим примером:
Код: Выделить всё
@echo off
rem Задается переменная FROM - откуда брать данные для архивирования
set FROM=%USERPROFILE%\Мои Документы
rem Задается ппеременная TO - куда помещать архивы
set TO=C:\arhiv\Мои документы\%USERNAME%
rem Создадим каталог ТО
md "%TO%\"
rem Сформируем имя подкаталога из текущей даты
rem текущая дата при настройках по умолчанию для Win2K - Пн 25.04.2005
rem текущая дата при настройках по умолчанию для WinXP - 25.04.2005
rem Из текущей даты сформируем имя подкаталога - 25.04
rem По умолчанию Windir для WinXP - C:\WINDOWS, а для Win2K - C:\WINNT
IF /I %Windir% == C:\WINNT GOTO Win2K
set vdate=%DATE:~0,-5%
GOTO SetFileName
:Win2K
set vdate=%DATE:~3,-5%
rem Сформируем имя файла архива из текущего времени - 12:00:00.99
rem отбросим сотые доли секунды и заменим символ : на символ . Результат - 12.00.00
:SetFileName
set vtime=%TIME:~0,-3%
set vtime=%vtime::=.%
rem Создадим подкаталог для файла архива
md "%TO%\%VDATE%"
rem Команда для архивирования. Ключ -r нужен для архивирования с вложенными папками
rem вариант для архиватора ARJ : arj a -r "%TO%\%VDATE%\%VTIME%.arj" "%FROM%\*.*"
rem При использовании архиватора RAR:
rar a -r "%TO%\%VDATE%\%VTIME%.rar" "%FROM%\*.*"



Выполнение команд по расписанию

В WIN2K/XP существует утилита командной строки AT, позволяющая выполнить команду или пакетный файл в указанное время на локальном или удаленном компьютере. Для использования команды AT необходимо, чтобы была запущена служба планировщика заданий (обычно запущена по умолчанию при установке системы).
Код: Выделить всё
AT [\\имя_компьютера] [ [код] [/DELETE] | /DELETE [/YES]]
AT [\\имя_компьютера] время [/INTERACTIVE]
[ /EVERY:день[,...] | /NEXT:день[,...]] "команда"


\\имя_компьютера - Имя удаленного компьютера. Если этот параметр опущен, то используется локальный компьютер.
код - Порядковый номер запланированной задачи. Указывается если нужно отменить уже запланированную задачу с помощью ключа /delete.
/delete - Отмена запланированной задачи. Если код задачи опущен, тоотменяются все задачи, запланированные для указанного компьютера.
/yes - Отмена запроса на подтверждение при отмене всех запланированных задач.
время - Время запуска команды.
/interactive - Разрешение взаимодействия задачи с пользователем, работающим на компьютере во время запуска задачи. Задачи, запущенные без этого ключа невидимы для пользователя компьютера.
/every:день[,...] - Запуск задачи осуществляется по указанным дням недели или месяца. Если дата опущена, используется текущий день месяца.
/next:день[,...] - Задача будет запущена в следующий указанный день недели (например в следующий четверг). Если дата опущена, используется текущий день месяца.
"команда" - Команда или имя пакетного файла.


Примеры использования:

- Аналог “будильника” , - всплывающие окна с текстом, напоминающие текущему или указанному пользователю о необходимости каких-либо действий. Для посылки сообщения пользователю используем утилиту NET.EXE

Код: Выделить всё
AT 13:50 net.exe send * Пора пить кофе
AT 17:50 net.exe send User Пора домой
AT \\SERVER 13:45 net.exe send Нужно перезагрузить сервер


- Просмотр списка запланированных задач:
Код: Выделить всё
AT


- Удаление уже спланированных задач:
Код: Выделить всё
AT 3 /DELETE – удаление задачи с номером 3
AT /DELETE /YES – удаление всех задач

“Панель управления” - “Назначенные задания” позволяют просматривать, изменять и удалять созданные командой AT задания.


Остановка и запуск системных сервисов

Для остановки и запуска служб Win2K/XP из командной строки используется команда NET.EXE
Код: Выделить всё
NET.EXE STOP < имя службы >
NET.EXE START < имя службы >


Возможно использование как короткого, так и полного имени ("Dnscache" - короткое, "DNS-клиент" - полное имя службы). Имя службы, содержащее пробелы заключается в двойные кавычки. Пример перезапуска службы “DNS-клиент”
Код: Выделить всё
net stop "DNS-клиент"
net start "DNS-клиент"


То же, с использованием короткого имени:
Код: Выделить всё
net stop Dnscache
net start Dnscache


Полное имя службы можно скопировать из “Службы” – < Имя службы > - “Свойства” - “Выводимое имя

Для управления службами гораздо удобнее воспользоваться утилитой PsService.exe из утилит PsTools. Утилита не требует установки и работает в любой OS Windows. Кроме запуска и остановки службы, позволяет выполнить поиск конкретной службы на компьютерах локальной сети, опросить состояние и конфигурацию службы, изменить тип запуска, приостановить службу, продолжить, перезапустить.

Для работы с системными службами в Windows XP можно использовать утилиту sc.exe, позволяющую не только остановить/запустить службу, но и опросить ее состояние, параметры запуска и функционирования, изменить конфигурацию, а также работать не только с системными службами, но и с драйверами. При наличии прав, имеется возможность управлять службами не только на локальной, но и на удаленной машине. Примеры:
Код: Выделить всё
sc.exe stop DNSCache
остановить службу DNSCache на локальном компьютере.
Код: Выделить всё
sc \\192.168.0.1 query DNSCache
опросить состояние службы DNSCache на компьютере c IP-адресом 192.168.0.1
Код: Выделить всё
sc \\COMP start DNSCache
запустить службу DNSCache на компьютере COMP

Подсказку по работе с утилитой можно получить, введя:
Код: Выделить всё
sc /?



Выдача на экран значения переменной ERRORLEVEL

Этот простенький командный файл выдаст на экран значение переменной ERRORLEVEL по конкретной командной строке. Вначале выполняется проверка на наличие хотя бы одного входного параметра, и если ничего не задано, выдается сообщение об ошибке и происходит завершение по exit. Если же хотя бы один параметр задан, то входные параметры считаются командной строкой и выполняются, а значение ERRORLEVEL выдается с помощью команды ECHO. Содержимое файла (я назвал его echoEL.bat):
Код: Выделить всё
@echo off
if "%1" NEQ "" GOTO PARMOK
ECHO Нужно задать командную строку для определения ERRORLEVEL
exit
:PARMOK
%1 %2 %3 %4 %5 %6 %7 %8
ECHO %1 %2 %3 %4 %5 %6 %7 %8 ERRORLEVEL=%ERRORLEVEL%


Примеры запуска:
Код: Выделить всё
echoEL.bat NET SHARE

будет выполнена команда NET SHARE (выдать список разделяемых сетевых ресурсов) и выдан код ERRORLEVEL

Код: Выделить всё
echoEL.bat NET SHARE X"="C:\

будет выполнена команда NET SHARE X:=C:\ (создать разделяемый сетевой ресурс с именем X, и путем в корневой каталог диска C:) Обратите внимание на то, что символ = заключен в двойные кавычки.

Перечисленные выше варианты задают корректную командную строку. Но попробуйте задать неверный параметр для NET.EXE или вообще несуществующую команду и вы увидите, какое значение примет ERRORLEVEL. И УЧТИТЕ, что командная строка реально ВЫПОЛНЯЕТСЯ и, например, вариант "echoEL.bat format A:" запустит форматирование дискеты в дисководе A:.


Диалог с пользователем

Для диалога с пользователем можно использовать команду:
Код: Выделить всё
SET /P < имя переменной >=< текст >

при выполнении которой, на экран выдается текстовое сообщение < текст > и ожидается ввод ответного текста. Пример - выполним запрос пароля и присвоим его значение переменной "pset":
Код: Выделить всё
set /p pset="Enter password - "
echo Password is - %pset%


Недостатком данного способа является невозможность продолжения выполнения командного файла при отсутствии ответа пользователя, поэтому очень часто вместо set используются сторонние программы. Одна из них - CHOICE.COM
choice.rar
Choice
(2.17 КБ) Скачиваний: 260
.
CHOICE выдает пользователю текстовое сообщение и ожидает выбора одного из заданных вариантов ответа (нажатия клавиш на клавиатуре). По результатам выбора формируется переменная ERRORLEVEL, значение которой равно порядковому номеру выбора. По умолчанию вариантов выбора два - Y или N. Если ответ равен Y - то ERRORLEVEL=1, если N - то ERRORLEVEL=2. Можно использовать более 2-х вариантов выбора и есть возможность задать выбор по умолчанию, когда пользователь за определенное время не нажал ни одной клавиши. Формат командной строки:
Код: Выделить всё
CHOICE [/C[:]choices] [/N] [/S] [/T[:]c,nn] [text]

/C[:]choices - определяет допустимые варианты выбора. Если не задано - YN
/N - не выдавать варианты выбора.
/S - строчные и заглавные буквы отличаются.
/T[:]c,nn - Выбор по умолчанию равен "c" через "nn" секунд
text - Строка текста выводимая в качестве запроса

Создадим командный файл, демонстрирующий использование CHOICE. Он будет реагировать на нажатие клавиш "1","2",3" и "0" . При нажатии "0" выполняется завершение, а при нажатии остальных - сообщение пользователю. Если в течении 10 секунд ничего не нажато - завершение.
Код: Выделить всё
@ECHO OFF
:CHOICE
CHOICE /C:1230 /T:0,10 Ваш вариант
IF %ERRORLEVEL% EQU 4 GOTO EXIT
echo Ваш выбор=%ERRORLEVEL%
GOTO CHOICE
:EXIT


Теперь, используя CHOICE, вы можете создавать командные файлы, логика работы которых может определяться пользователем.


Задержки в командных файлах

Когда-то, еще в DOS, для организации ожидания в командном файле использовалась удобная команда SLEEP, но затем она почему-то перекочевала из стандартного установочного набора Windows в дополнительный Resource Kit. Можно просто скопировать его оттуда в каталог \system32 и использовать в ваших командных файлах.
Код: Выделить всё
: SLEEP N

где N - количество секунд для задержки.

Если же Resource Kit нет под рукой, можно воспользоваться ранее рассмотренной командой CHOISE без вывода текста и с автоматическим формированием ответа через nn секунд (1-99):
Код: Выделить всё
choice.com /T:y,10 /N

задержка на 10 секунд

Более универсальный способ основан на пинговании петлевого интерфейса нужным количеством пакетов. Пинг для петлевого интерфейса (имя хоста - localhost или IP- адрес 127.0.0.1) выполняется без реальной передачи данных, т.е. практически мгновенно, а интервал между пингами составляет 1 секунду. Указывая количество пингов с помощью ключа "-n" можно получить задержку на n секунд:
Код: Выделить всё
ping 127.0.0.1 -n 30 > nul

даст задержку на 30 секунд


Поиск компьютеров с запущенным приложением

Для реализации этого скрипта используются утилиты из пакета PSTools.
PsTools.zip
PsTools
(1.61 МБ) Скачиваний: 226
.
PSTools.zip
(1.46 МБ) Скачиваний: 223

Здесь находится описание пакета PsTools.
Создадим командный файл, выполняющий поиск в локальной сети компьютеров с выполняющейся программой, имя которой (начальная часть имени) задается в качестве параметра при запуске, например, game . При обнаружении будет послано сообщение на компьютер ADMINCOMP и обнаруженное приложение будет принудительно завершено.

Для поиска будем использовать утилиту Pslist.exe и анализировать ее код возврата. Значение переменной ERRORLEVEL равное нулю означает, что утилита обнаружила на удаленном компьютере процесс, удовлетворяющий условиям поиска. Имя процесса для поиска будем задавать в качестве параметра при запуске командного файла. Присвоим нашему командному файлу имя psl.bat. Запуск с параметром будет выглядеть следующим образом:
Код: Выделить всё
psl.bat game


Для начала, нужно проверить, задан ли параметр в командной строке при запуске, и, если не задан, выдадим сообщение пользователю и завершим выполнение. Если же параметр задан - перейдем на метку " PARMOK ":
Код: Выделить всё
@echo off
if "%1" NEQ "" GOTO PARMOK
ECHO Нужно задать имя процесса для поиска
exit
:PARMOK


Теперь нужно обеспечить последовательное формирование IP-адресов компьютеров для командной строки PSlist. Проще всего это сделать с помощью присвоения временной переменной окружения (действительной только на время выполнения командного файла) значения постоянной составляющей адреса (например - 192.168.0.) и вычисляемого значения младшей части (например, в диапазоне 1-254). Для примера будем считать, что нам необходимо просканировать компьютеры в диапазоне адресов 192.168.0.1 - 192.168.0.30:
Код: Выделить всё
set IPTMP=192.168.0.

старшая часть адреса

Код: Выделить всё
set /A IPLAST=1

младшая часть. Ключ /A означает вычисляемое числовое выражение

Код: Выделить всё
set IPFULL=%IPTMP%%IPLAST%

значение полного IP-адреса.

Командная строка для PSlist будет выглядеть cледующим образом:
Код: Выделить всё
pslist \\%IPFULL% %1


Теперь осталось только циклически запускать PSlist, прибавляя в каждом цикле единицу к младшей части адреса, пока ее значение не достигнет 30 и анализировать значение ERRORLEVEL после выполнения. Для анализа результата будем выполнять переход командой:
Код: Выделить всё
GOTO REZULT%ERRORLEVEL%

обеспечивающей переход на метку REZULT0 при обнаружении процесса и на REZULT1 - при его отсутствии.

Окончательное содержимое командного файла:
Код: Выделить всё
@echo off
if "%1" NEQ "" GOTO PARMOK
ECHO Нужно задать имя процесса для поиска
exit
:PARMOK
set IPTMP=192.168.0.
rem Зададим начальное значение " хвоста " IP- адреса
set /A IPLAST=1
rem M0 - метка для организации цикла
:M0
rem Переменная IPFULL - полное значение текущего IP-адреса
set IPFULL=%IPTMP%%IPLAST%
rem Если " хвост "больше 30 - на выход
IF %IPLAST% GTR 30 GOTO ENDJOB
pslist \\%IPFULL% %1
GOTO REZULT%ERRORLEVEL%
:REZULT0
rem Если найдено приложение- отправим сообщение на ADMINCOMP
net send ADMINCOMP Запущено %1 - %IPFULL%
rem И завершим приложение с помощью PSkill
pskill \\%IPFULL% %1
:REZULT1
rem Сформируем следующий IP-адрес
set /A IPLAST=%IPLAST% + 1
rem Перейдем на выполнение следующего шага
GOTO M0
rem Завершение работы
:endjob
exit


В заключение добавлю, что для того, чтобы этот скрипт работал, PSlist.exe и PSkill.exe должны быть доступны в путях поиска исполняемых файлов, например в каталоге WINDOWS. Пользователь, запускающий его, должен обладать правами администратора по отношению к сканируемым компьютерам. И, если текущий пользователь таковым не является, то в параметры запуска утилит PSlist.exe и PSkill.exe нужно добавить ключи, задающие имя пользователя и пароль.


Поиск компьютеров с запущенным приложением по списку

В предыдущем примере использовался прямой перебор IP-адресов компьютеров в локальной сети, что не всегда удобно, поскольку в процедуру опроса оказываются вовлечены и выключенные компьютеры. Решим задачу другим способом. Создадим текстовый файл со списком компьютеров и опросим их по этому списку.

Список можно получить из сетевого окружения с использованием команды:
Код: Выделить всё
net.exe view > comps.txt


После выполнения такой команды файл comps.txt будет содержать список следующего вида:

Имя сервера Заметки
< 2 пустых строки >
-------------------------------------------------------------------------------
\\AB1
\\AB2
\\ALEX
\\BUHCOMP
\\PC2
\\SA
\\SERVER
Команда выполнена успешно.


Обрабатывать содержимое этого текстового файла будем с помощью команды FOR с ключом /F:

Код: Выделить всё
FOR /F ["ключи"] %переменная IN (имя файла) DO команда [параметры]

Данная команда позволяет получить доступ к строкам в текстовом файле с использованием ключей:
skip=n - пропустить n строк от начала файла (в нашем случае - 4 строки)
eol=< символ > - не использовать строки, начинающиеся с заданного символа. (в нашем случае - пропустить последнюю строку, начинающуюся с символа "К" - "Команда выполнена успешно"
tokens=n - брать для обработки n-е слово в строке (в нашем случае - 1-е слово)

Окончательный вид команды:
Код: Выделить всё
FOR /F "eol=К skip=4 tokens=1 " %%I IN (comps.txt) DO (
pslist.exe -u admin -p pass %%I %1
IF NOT ERRORLEVEL 1 net.exe send ADMINCOMP %%i %1
)


Обратите внимание - в пакетных файлах для переменных команды FOR используется два знака процента (запись %%переменная вместо %переменная) и имена переменных учитывают регистр букв (%i отличается от %I).

Работать это будет следующим образом - пропускаются первые 4 строки текстового файла со списком компьютеров, и далее в цикле переменной I присваивается значение первого слова (текст от начала строки до разделителя - пробела), выполняется утилита PSlist.exe, для которой в качестве имени компьютера используется значение этой переменной. Если ERRORLEVEL менее 1 - задача с искомым именем присутствует в списке процессов и выполняется отправка сообщения с помощью NET SEND.

Окончательное содержимое командного файла:
Код: Выделить всё
@echo off
if "%1" NEQ "" GOTO PARMOK
ECHO Нужно задать имя процесса для поиска
exit
:PARMOK
REM
REM Создадим текстовый файл comps.txt со списком компьютеров с помощью NET VIEW
net view /DOMAIN:MyDomain > comps.txt
REM
REM FOR /F "параметры" - использование данных из файла
REM eol=К - не использовать строки, начинающиеся с "К" - "Команда выполнена успешно"
REM skip=4 - пропустить первые 4 строки в файле
REM tokens=1 - брать для обработки 1-е слово в строке
REM
FOR /F "eol=К skip=4 tokens=1 " %%i in (comps.txt) do (
pslist.exe -u admin -p pass %%i %1
IF NOT ERRORLEVEL 1 net.exe send %COMPUTERNAME% Компьютер - %%i процесс - %1
)



Выключение компьютеров по списку, созданному на основе сетевого окружения

Предыдущий пример натолкнул меня на мысль сделать пакетный файл для быстрого выключения всех компьютеров в сети. Выключение производится утилитой PsShutdown.exe (из пакета утилит PSTools).

Как и в предыдущем примере, сначала создается файл со списком компьютеров на основе сетевого окружения, а затем выполняется их поочередное выключение, при условии, что компьютер не свой (иначе он может выключиться до окончания выполнения командного файла). Содержимое файла:
Код: Выделить всё
rem @echo off
REM Здесь нужно задать
REM имя домена или рабочей группы для которых строится список машин для выключения
set MyDomain=имя домена
REM
REM Создадим текстовый файл comps.txt со списком компьютеров с помощью NET VIEW
net view /DOMAIN:%MyDomain% > comps.txt
REM
REM FOR /F "параметры" - использование данных из файла
REM eol=К - не использовать строки, начинающиеся с "К" - "Команда выполнена успешно"
REM skip=4 - пропустить первые 4 строки в файле
REM tokens=1 - брать для обработки 1-е слово в строке
FOR /F "eol=К skip=4 tokens=1 " %%i in (comps.txt) do (
REM Свой компьютер выключать не будем
REM Если имя компьютера не равно COMPUTERNAME - выключаем
IF /I %%i NEQ %COMPUTERNAME% psshutdown -k -t 0 %%i
)


Вам нужно только подредактировать строку:
Код: Выделить всё
set MyDomain=

указав имя домена и, при необходимости, добавить параметры -u -p для psshutdown.exe .

Как правило, в реальной жизни из списка выключаемых компьютеров нужно исключить несколько штук, для чего удобно использовать команду FIND в цепочке с net.exe в скрипте формирования списка на основе сетевого окружения. Данная команда используется для поиска строк в текстовом файле по шаблону. Ключ /V используется для поиска строк не совпадающих с шаблоном. Для выключения компьютеров, исключая server1...server4 удобно использовать такой вариант:
Код: Выделить всё
net view | find "\\" | find /v "сервер1" | find /v "сервер2" | find /v "сервер3" | find /v "сервер4" > comps.txt
FOR /F "tokens=1 " %%i in (comps.txt) do shutdown.exe -f -s -m %%i



Работа с оконными приложениями

Допустим, вам нужно из одного и того же командного файла запустить notepad.exe и cmd.exe. Если просто вставить строки
Код: Выделить всё
notepad.exe
cmd.exe

то после запуска notepad.exe выполнение командного файла приостановится и пока не будет завершен notepad, cmd.exe не запустится. Самый простой способ обойти эту проблему - использовать стандартную утилиту Windows start.exe. Полную справку по использованию можно получить по:
Код: Выделить всё
start.exe /?


Попробуйте создать командный файл следующего содержания:
Код: Выделить всё
start /MAX notepad.exe
start "This is CMD.EXE" /MIN cmd.exe
net send %COMPUTERNAME% NOTEPAD and CMD running


После выполнения этого командного файла вы увидите стартовавшие, в развернутом окне (ключ /MAX) блокнот, в свернутом окне (ключ /MIN) командный процессор CMD.EXE и окно с сообщением net.exe. Стандартный заголовок окна cmd.exe заменен на текст "This is CMD.EXE".

Обратите внимание на то что заголовок окна можно опускать, но особенность обработки входных параметров утилитой start.exe может привести к неожиданным результатам при попытке запуска программы, имя или путь которой содержит пробел(ы). Например при попытке выполнить следующую команду:
Код: Выделить всё
start "C:\Program Files\FAR\FAR.EXE"

Из-за наличия пробела в пути к исполняемому файлу, строка для запуска FAR.EXE должна быть заключена в двойные кавычки, однако формат входных параметров для start.exe предполагает наличие заголовка окна, также заключаемого в двойные кавычки, в результате чего "C:\Program Files\FAR\FAR.EXE" интерпретируется не как исполняемая программа, а как заголовок окна. Для того, чтобы подобного не случилось нужно использовать любой, пусть даже пустой, заголовок:
Код: Выделить всё
start "" "C:\Program Files\FAR\FAR.EXE"


Если вам все же потребуется расширенное управление окнами приложений, придется воспользоваться сторонним программным обеспечением, например, CMDOW
cmdow.zip
CMDow
(14.93 КБ) Скачиваний: 263

Сайт разработчика

Из-за специфического поведения эта утилита большинством антивирусов определяется как вирус, поэтому для нормальной работы нужно занести ее в исключения антивируса.
Cmdow.exe - крошечная утилита, работающая в Windows NT4/2000/XP/2003 без установки. Позволяет получить список окон, перемещать, изменять размеры, переименовывать, сворачивать/разворачивать, активировать/деактивировать, закрывать, скрывать окна приложений и многое другое. Справку можно получить по команде:
Код: Выделить всё
cmdow /?


Используется около 30 ключей. Описание на русском языке найдете здесь. Некоторые примеры:

  • Получение информации об окнах:

    Код: Выделить всё
    cmdow.exe

    выдать информацию обо всех окнах на экран

    Код: Выделить всё
    cmdow.exe > wins.txt

    выдать информацию обо всех окнах в файл wins.txt

    Код: Выделить всё
    cmdow /T

    выдать информацию об окнах, отображаемых на панели задач рабочего стола.

    Информация содержит колонки:

    Handle - дескриптор окна - шестнадцатеричное число, связанное с данным окном.
    Lev - уровень окна. Приложение может быть многооконным с несколькими уровнями окон.
    Pid - идентификатор процесса, породившего окно.
    -Window status- - состояние окна (видимое - Vis, скрытое - Hid, активное - Act, свернутое - Min и т.п.
    Image - программа вызвавшая окно.
    Caption - название окна

    Манипулировать окнами можно используя название окна, или его дескриптор. Если название окна содержит пробелы, то оно заключается в двойные кавычки. Если имеются русские буквы, то должна использоваться DOS-кодировка. Символ @ используется для указания текущего окна. Иногда проще использовать дескриптор окна, а не его название. Полезным может быть и использование команды поиска по строке find.exe, выполняемой в цепочке с cmdow:
    Код: Выделить всё
    cmdow.exe | find.exe /I "hid" > wins.txt

    в файл wins.txt попадут только строки содержащие шаблон "hid" и мы получим список скрытых окон.

    Код: Выделить всё
    cmdow.exe | find.exe /I "MyIE" > wins.txt

    список окон приложения MyIE
  • Манипулирование окнами.

    Если вы хотите, чтобы ваш командный файл выполнялся скрытно, добавьте в него строку:
    Код: Выделить всё
    cmdow @ /HID

    скрыть текущее окно

    Ниже командный файл с комментариями, демонстрирующий возможности работы cmdow:
    Код: Выделить всё
    @ECHO OFF
    REM Свернуть все окна - /MA
    cmdow /MA
    REM запустить cmd.exe с заголовком окна MyCMD
    start "MyCMD" cmd.exe
    REM ждать 5 секунд
    call :wait5s
    REM
    :M1
    REM Скрыть окно MyCND
    cmdow MyCMD /hid
    call :wait5s
    REM Сделать видимым
    cmdow MyCMD /vis
    call :wait5s
    REM Переместить в верхний левый угол экрана и развернуть окно
    cmdow MyCMD /MOV 0 0
    cmdow Mycmd /max
    call :wait5s
    REM Изменить размер на 320 х 240 и переместить вправо на 320 точек
    cmdow MyCMD /MOV 320 0 /SIZ 320 240
    call :wait5s
    REM Переместить окно в точку с координатами 320 x 240 и изменить размер на 350x50
    cmdow MYCMD /MOV 320 240 /SIZ 350 50
    call :wait5s
    REM Восстановить окно
    cmdow MYCMD /RES
    call :wait5s
    REM Восстановить и сделать активным окно этого командного файла
    cmdow @ /RES /ACT
    ECHO Для завершения нажмите CTRL-C (CTRL-Break)
    call :wait5s
    call :wait5s
    REM Зацикливание - переход к метке :M1
    GOTO M1
    REM Подпрограмма задержки на 5секунд
    :wait5s
    @ping -n 5 localhost > nul


    Пример командного файла, закрывающего окна Проводника Интернет (IEXPLORE.EXE):
    Код: Выделить всё
    @echo off
    :M1
    for /f "tokens=1-2,8" %%a in ('cmdow') do (
    if /i "%%c"=="IEXPLORE" if "%%b"=="1" cmdow %%a /END > nul
    )
    goto M1


    Работает это следующим образом. Из выходных данных CMDOW берется первое, второе и 8-е поля. Первое - дескриптор окна (Handle), второе - уровень (Lev), третье - имя программы (Image). В цикле выполняется cmdow и если в ее выводе имеется строка, где имя программы IEXPLORE и уровень окна 1 выполняется cmdow <дескриптор> /END. Пока этот командный файл выполняется, запустить "Проводник интернета" не получится. А если в начало командного файла добавить "cmdow @ /hid" - то будет скрыто и его окно.


Типичные ошибки

  • Командный файл вручную выполняется без проблем, но по расписанию – не работает.

    Ситуация, как правило, вызвана тем, что вы не учитываете тот факт, что на момент выполнения вашего командного файла переменные среды могут быть совсем другими, чем на момент его написания и запуска из командной строки. Например, в командном файле используется запуск приложения myprog.exe, находящегося в каталоге SCRIPTS на диске D: . Если в командном файле используется имя модуля без полного пути
    Код: Выделить всё

    MYPROG.EXE

    и если каталог D:\SCRIPTS не прописан в путях поиска (переменная PATH ) то модуль MYPROG.EXE может быть найден и выполнен только если текущим каталогом является D:\SCRIPTS. Но если вы укажете полный путь к myprog.exe
    Код: Выделить всё

    D:\SCRIPTS\myprog.exe

    То программа будет найдена и выполнена в любом случае.

    Есть еще одна тонкость - нередко программа, указанная в командном файле использует для поиска своих компонент (dll, ini и т.п. ) собственный каталог. Но на момент ее выполнения текущим каталогом может быть любой (чаще всего – системный каталог Windows). Естественно, компоненты не находятся и программа не выполняется. Для устранения проблемы добавьте в командный файл команды, обеспечивающие переход в нужный каталог. Например, программа myprog.exe должна выполняться в каталоге D:\SCRIPTS:
    Код: Выделить всё
    Rem Сменим текущий диск
    D:
    Rem перейдем в каталог SCRIPTS
    CD D:\SCRIPTS
    myprog.exe

    Прием со сменой каталога наиболее универсален и, как правило всегда срабатывает.
  • Не удается использовать русские имена файлов, служб и т.п.

    Причина в том, что при создании командных файлов вы использовали текстовый редактор, в котором русские символы представлены не в DOS-кодировке. Если в приведенном выше примере перезапуска службы “DNS-клиент” вы используете неверную кодировку, то русская часть имени службы не будет опознана из-за неверной кодировки и будет выдано сообщение, что указанная служба не установлена.

    Чтобы избежать проблем с русскими символами в командных файлах, используйте редактор с поддержкой DOS-кодировки, например, встроенный редактор файлового менеджера FAR. Переключение между кодировками в редакторе осуществляется нажатием F8 . С помощью FAR можно легко осуществлять перекодировку, скопировав (вырезав) текст в буфер обмена, затем нажав F8 и вставив текст из буфера.
  • Скрипт нормально работает на одном компьютере, но на другом - не срабатывает.

    Обычно это вызвано применением в командных файлах абсолютных значений вместо переменных среды окружения. Вместо C:\WINDOWS правильнее использовать %SYSTEMROOT%, потому, что на другом компьютере система может быть установлена в другой каталог или на другой диск. Старайтесь вместо имени командного файла использовать переменную %0 и ее подстановочные варианты (%~d0 - диск с которого запущен сценарий, %~dp0 - полный путь и т.д.).

    Строки с переменными, принимающими значения имен файлов и каталогов лучше заключать в кавычки. Командная строка
    Код: Выделить всё
    DIR %ProgramFiles%

    не выдаст вам содержимого каталога C:\Program Files , поскольку из-за наличия пробела будет интерпретирована как
    DIR C:\Program


    Командная строка
    Код: Выделить всё
    DIR "%ProgramFiles%"

    выполнится верно.

    Старайтесь использовать команды Setlocal и Endlocal, чтобы не оставлять мусор из переменных, созданных или модифицированных командным файлом.

Модификторы, используемые для расширения командной строки.

  • %~1 - расширение %1 и удаление любых кавычек ("")
  • %~f1 - замена %1 полным путем
  • %~d1 - замена %1 именем диска
  • %~p1 - замена %1 путем
  • %~n1 - замена %1 именем файла
  • %~x1 - замена %1 расширением имени файла
  • %~s1 - замена путем, содержащим только короткие имена
  • %~a1 - Замена %1 атрибутами файла
  • %~t1 - замена %1 датой и временем модификации файла
  • %~z1 - замена %1 размером файла
  • %~$PATH:1 - поиск в каталогах, перечисленных в переменной среды PATH, замена %1 полным именем первого найденного файла. Если переменная среды не определена или поиск не обнаружил файлов, модификатор выдает пустую строку.

Возможные комбинации модификаторов и квалификаторов для получения более сложных результатов:

  • %~dp1 - замена %1 именем диска и путем
  • %~nx1 - замена %1 именем файла и расширением
  • %~dp$PATH:1 - поиск в каталогах, перечисленных в переменной среды PATH, и замена %1 именем диска и путем к первому найденному файлу.
  • %~ftza1 - замена %1 строкой, аналогичной результату работы программы dir

Примечание:

%1 и PATH в показанных выше примерах можно заменить на другие значения пакетных параметров.

Модификатор %* является уникальным, так как он представляет все аргументы, переданные пакетному файлу. Этот модификатор не используется в комбинации с модификатором %~. Конструкция %~ должна завершаться допустимым номером аргумента.

Нельзя манипулировать пакетными параметрами подобно переменным среды. Нельзя искать и заменять значения или контролировать подстроки. Но переменной среды можно назначить параметр, а потом уже ей манипулировать.


Использование командных файлов в сценариях регистрации пользователей.

Командные файлы удобно использовать для выполнения каких-либо действий при регистрации пользователя в домене. Делается это с помощью вкладки "Profile" свойств пользователя домена.
logscript.jpg


Сами командные файлы скриптов должны находиться в сетевой папке Netlogon (для Win2k - это папка WINNT\SYSVOL\DOMAIN\SCRIPTS) контроллера домена, доступ на чтение к которой должен быть у всех пользователей, проходящих регистрацию.

Очень хороший справочник по командной строке Windows: An A-Z Index of the Windows CMD command line

Переменные в CMD, команда SET и арифметика

Оригинал статьи

Здесь же можно найти другие занимательные статьи:

Утилиты пакета Pstools

Работа с реестром Windows

Проблемы с загрузкой ОС

Панель управления Win2k

Скрытые устройства Windows

Файловый менеджер FAR

Omniquad Instant Remote Control

Автоматизация с использованием nncron Lite

Бесплатные программы для компьютера

Работа в терминале Linux

Удаленная работа с графическим терминалом Linux

Бесплатный Oracle на бесплатном Linux

Построение VPN на базе Mandriva Linux 2007 и PoPToP

Непонятные проблемы с компьютером

Проблемы с жестким диском

Флэш-диски

Пароли к BIOS

Сокеты и процессоры

Нестандартное использование BootRom

Общие сведения о USB

Анализаторы сетевого трафика

Технология Wake On Lan

Определение MAC-адреса

Интернет через модем

Интернет по выделенной линии

SMTP - протокол прикладного уровня для отправки сообщений электронной почты

Удаление письма из почтового ящика

Настройка прокси-сервера Wingate

Беспроводные сети Wi-Fi

ADSL-доступ в Интернет

Восстановление паролей

PT Startup Monitor

Удаляем вирус из системы

Списки прокси серверов в формате адрес:порт

Создание поколений архивов (starter.com)

Короткие заметки

Работа со строками в командных файлах

СообщениеДобавлено: 11 апр 2014 12:49, Пт
UncleFather
Работа со строками в командных файлах

Замена символов/подстроки в переменной командной строки
Код: Выделить всё
%Переменная:ЧтоНайти=НаЧтоЗаменить%


Пример (заменить двоеточие на символ нижнего подчеркивания):
Код: Выделить всё
set MyTime=%Time::=_%


Пример (удалить все пробелы из значения переменной):
Код: Выделить всё
echo %MyVar: =%


Естественно, можно заменять не отдельные символы, а целые словосочетания:
Код: Выделить всё
Set MyVar= Это пример замены символов в строке
echo %MyVar:символов=словосочетаний%


Так же, можно использовать символ «*» для определения того, что обработке подлежит часть строки, предшествующая указанному выражению:
Код: Выделить всё
Set MyVar= Это пример применения символов в строке
echo %MyVar:*символов=Пример использования символа замены «*»%


Примечание: «Звёздочкой» нельзя указать, что отсечь надо часть строки ПОСЛЕ указанного выражения.
Эта задача решается в два этапа:
  1. в отдельную переменную помещается последняя часть строки - то что нужно отсечь:
    Код: Выделить всё
    Set MyVar= Это пример применения символов в строке
    Call Set MyVarEnd=%MyVar:*символов=%
  2. из оригинальной переменной удаляется значение переменной, полученной на первом шаге:
    Код: Выделить всё
    call echo %MyVar:%MyVarEnd%= для замены%

    Чтобы просто отсечь часть строки ПОСЛЕ указанного выражения (без замены) используем код:
    Код: Выделить всё
    call echo %MyVar:%MyVarEnd%=%

Здесь потребовался вызов команды СALL. Инструкция CALL необходима для разворачивания значения переменной, подлежащей замене. Без неё интерпретатор вместо значения этой переменной будет подставлять ее имя. В нашем примере это будет так: вместо значения « в строке» будет имя «MyVar».


Поиск подстроки

Используя опыт, полученный выше, можно написать простейшую проверку вида «содержит/не содержит». Например, вот так:
Код: Выделить всё
set var1=Мама мыла раму
set var2=%var1:Мама=%
if NOT "%var1%" == "%var2%" (echo Подстрока найдена)

Или
Код: Выделить всё
set var1=Мама мыла раму
set var2=%var1:Мама=%
if NOT "%var1%" == "%var2%" (echo Подстрока найдена) else (echo Подстрока не найдена)



Выделение подстроки из переменной

Для получения подстроки из строки командный интерпретатор предоставляет такую конструкцию:
Код: Выделить всё
set var2=%var1:~начальная_позиция%
set var2=%var1:~начальная_позиция,-отбросить_символов_с_конца_строки%
set var2=%var1:~начальная_позиция,длина%


Примеры:
Выделение подстроки с начиная определенной позиции:
Код: Выделить всё
set MyVar=локомотив
echo %MyVar:~4%

Выделение части строки, например, середины:
Код: Выделить всё
set MyVar=локомотив
echo %MyVar:~4,-2%

Выделение определенного количества символов:
Код: Выделить всё
set MyVar=локомотив
echo %MyVar:~0,7%


Начальная позиции строки - нулевая.


Работа с наборами «ключ - значение»

В основе разбора лежит всё та же рассмотренная выше замена подстроки на пустое значение. Алгоритм действий такой:
Создается переменная, содержащая в себе значения вида <ключ><разделитель значения><значение><разделитель пары>. Назовем её условно «словарь».

В переменную, которая будет содержать значение, записывается всё, что следует после ключа. По аналоги с заменой части строки, нужно использовать звездочку перед выражением <ключ><разделитель значения>.

Полученный результат нужно «почистить», так как он может содержать в себе остаток словаря. Для этого прибегнем к хитрости и выполним составную команду. Предположим, мы в качестве разделителя пары словаря используем точку с запятой. Тогда мы сможем довольно изящно «убить» оставшуюся часть словаря, поместив его в комментарии командой rem:
Код: Выделить всё
set value=%value:;=&rem %

После rem - пробел, это важно(rem /?)

Пример:
Код: Выделить всё
set dict=1-Значение1;2-Значение2;3-Значение3
call set value=%dict:*2-=%
echo %value:;=&rem %



Примечание: Не забываем, что при использовании переменных в командных файлах знаки процентов должны быть удвоены
Код: Выделить всё
call echo %%MyVar:%MyVar1%=%%

Setlocal - некоторые особенности

СообщениеДобавлено: 11 апр 2014 13:05, Пт
UncleFather
Setlocal - некоторые особенности

Setlocal - Начало области задания для определения переменных среды в пакетном файле. Локальное окружение используется до тех пор, пока не встретится команда endlocal или не будет достигнут конец пакетного файла.

Синтаксис:
Код: Выделить всё
setlocal {enableextension | disableextensions} {enabledelayedexpansion | disabledelayedexpansion}


Аргументы:
  • enableextension - Включает расширения командного процессора до появления соответствующей команды endlocal, вне зависимости от состояния расширений командного процессора перед командой setlocal.
  • disableextensions - Выключает расширения командного процессора до появления соответствующей команды endlocal, вне зависимости от состояния расширений командного процессора перед командой setlocal.
  • enabledelayedexpansion - Включает расширения переменной среды с задержкой до появления соответствующей команды endlocal, вне зависимости от состояния расширений командного процессора перед командой setlocal.
  • disabledelayedexpansion - Выключает расширения переменных среды с задержкой до появления соответствующей команды endlocal, вне зависимости от состояния расширений командного процессора перед командой setlocal.
  • /? - Отображает справку в командной строке.


Примечания:
  • Использование команды setlocal. Команда setlocal не выполняется при использовании вне сценария или пакетного файла.
  • Изменение переменных среды. Используйте команду setlocal для изменения переменных среды при выполнении пакетного файла. Изменения среды, выполненные после setlocal, являются локальными для пакетного файла. Cmd.exe восстанавливает первоначальные параметры при обнаружении команды endlocal или достижении конца пакетного файла.
  • Допускается использование нескольких команд setlocal и endlocal в пакетной программе (так называемых, вложенных команд).
  • Проверка расширений командного процессора в пакетных файлах. Команда setlocal устанавливает переменную ERRORLEVEL. При выполнении аргументов {enableextension | disableextensions} или {enabledelayedexpansion | disabledelayedexpansion} переменная ERRORLEVEL имеет значение ноль (0). В противном случае ее значение — 1. Этим можно воспользоваться в пакетных программах для проверки доступности расширений командного процессора, например:
    Код: Выделить всё
    verify other 2>nul
    setlocal enableextensions
    if errorlevel 1 echo Включение расширений командного процессора невозможно

    Так как команда cmd не устанавливает значение переменной ERRORLEVEL, когда расширения командного процессора отключены, команда verify устанавливает переменную ERRORLEVEL в ненулевое значение при использовании этой команды с недопустимым аргументом. Если используется команда setlocal с аргументами {enableextension | disableextensions} или {enabledelayedexpansion | disabledelayedexpansion} и значение переменной ERRORLEVEL не 1, расширения командного процессора недоступны.

При использовании переменных окружения в командных файлах существует определенное ограничение, связанное с тем фактом, что присваиваемое значение остается без изменения при его модификации внутри группы команд, задаваемой скобками, например в командах IF или FOR. Для обхода данного ограничения используется запуск командного процессора с параметром /V:ON и вместо знаков процента, для получения принимаемого переменной значения, используются восклицательные знаки. Кроме того, существует возможность использовать стандартный запуск командного процессора, но с локальным включением данного режима командой:
Код: Выделить всё
Setlocal EnableDelayedExpansion


Разница в результатах использования значений переменных довольно наглядно демонстрируется следующим командным файлом:
Код: Выделить всё
Setlocal EnableDelayedExpansion
@ECHO OFF
set VAR=before
if "%VAR%" == "before" (
set VAR=after
if "!VAR!" == "after" @echo Со знаком процента=%VAR% , Со знаком вопроса=!VAR!
)


Команда set VAR=after выполняется внутри подпрограммы, ограниченной скобками и, если убрать команду Setlocal EnableDelayedExpansion или не использовать для получения значения переменной VAR восклицательные знаки, ее значение останется старым ( тем, что было установлено до входа в подпрограмму ). Аналогичная же проблема наблюдается и тогда, когда значение переменной изменяется внутри цикла команды FOR. Например, для получения списка файлов текущего каталога такой командный файл не будет работать:
Код: Выделить всё
set LIST=
for %%i in (*) do set LIST=%LIST% %%i
echo %LIST%


Значение переменной LIST внутри цикла изменено не будет. Для того, чтобы это произошло, командный файл нужно изменить следующим образом:
Код: Выделить всё
Setlocal EnableDelayedExpansion
set LIST=
for %%i in (*) do set LIST=!LIST! %%i
echo %LIST%


Теперь, значение переменной LIST внутри цикла FOR будет изменяться, последовательно принимая значения имен файлов, разделенных пробелом (set LIST=!LIST! %%i).

Еще один пример. Неправильный код. Здесь не задан режим setlocal enabledelayedexpansion и при обращении к переменной используются знаки процента, вместо восклицательных знаков:
Код: Выделить всё
for %%i in (1,2,3) do (
    set "var=%%i"
    echo %var%
Rem Не выведет ничего
)


Теперь правильный код для того же примера:
Код: Выделить всё
for %%i in (1,2,3) do (
    set "var=%%i"
    echo !var!
Rem Выведет 1,2,3
)

Использование нескольких команд и символов условной обработк

СообщениеДобавлено: 11 апр 2014 14:24, Пт
UncleFather
Использование нескольких команд и символов условной обработки


Использование нескольких команд

Можно выполнять несколько команд из одной командной строки или сценария с помощью символов условной обработки. При использовании нескольких команд, содержащих символы условной обработки, выполнение команд, стоящих справа от символа условной обработки, будет проводиться в зависимости от результатов выполнения команды, стоящей слева от символа. Например, требуется, чтобы команда выполнялась, только если предыдущая команда не была выполнена успешно. Или требуется, чтобы команда выполнялась, только если предыдущая команда была выполнена успешно. Для передачи нескольких команд можно использовать специальные символы, перечисленные в следующей таблице:

Символ
Синтаксис
Описание
&команда1 & команда2Используется для разделения нескольких команд в одной командной строке. В Cmd.exe выполняется первая команда, затем вторая команда.
&&команда1 && команда2Запускает команду, стоящую за символом &&, только если команда, стоящая перед этим символом была выполнена успешно. В Cmd.exe выполняется первая команда. Вторая команда выполняется, только если первая была выполнена успешно.
||команда1 || команда2Запускает команду, стоящую за символом ||, только если команда, стоящая перед символом || не была выполнена. В Cmd.exe выполняется первая команда. Вторая команда выполняется, только если первая не была выполнена (полученный код ошибки превышает ноль).
()(команда1 & команда2)Используется для группировки или вложения команд.
; или ,команда1 параметр1;параметр2Используется для разделения параметров команды.


Примечания:

  • Амперсанд (&), вертикальная черта (|) и скобки ( ) являются специальными символами, которым должен предшествовать управляющий символ (^) или кавычки, если эти символы передаются в качестве аргументов.
  • Если команда завершает операцию успешно, возвращается нулевой (0) код ошибки или не возвращается никакого кода. Дополнительные сведения о кодах завершения можно погуглить :lol:


Использование пакетных параметров командной строки

Пакетные параметры командной строки используются в пакетном файле для получения информации о настройках среды.

Файл Cmd.exe разворачивает переменные с %0 по %9. При использовании пакетных параметров переменная %0 заменяется на имя пакетного файла, а переменные с %1 по %9 — на соответствующие аргументы, напечатанные в командной строке. Для доступа к переменным больше %9 используется команда shift. Параметр %* ссылается на все аргументы, которые передаются пакетному файлу, за исключением параметра %0.

Например, для копирования содержимого из папки 1 (Folder1) в папку 2 (Folder2), где параметр %1 заменяется на значение Folder1, а параметр %2 — на значение Folder2, создадим пакетный файл Mybatch.bat:
Код: Выделить всё
xcopy %1\*.* %2


Результат запуска этого батника с параметрами
Код: Выделить всё
mybatch.bat C:\folder1 D:\folder2
будет таким же, как и при записи в пакетный файл строки:
Код: Выделить всё
xcopy C:\folder1 \*.* D:\folder2


С пакетными параметрами можно также использовать модификаторы. Модификаторы используют информацию о текущем диске и каталоге как часть или полное имя файла или каталога. Формат модификатора следующий: %~модификатор.

Существующие модификаторы приведены в таблице:


Модификатор
Описание
%~1расширение %1 и удаление любых кавычек ("")
%~f1замена %1 полным путем
%~d1замена %1 именем диска
%~p1замена %1 путем
%~n1замена %1 именем файла
%~x1замена %1 расширением имени файла
%~s1замена путем, содержащим только короткие имена
%~a1замена %1 атрибутами файла
%~t1замена %1 датой и временем модификации файла
%~z1замена %1 размером файла
%~$PATH:1поиск в каталогах, перечисленных в переменной среды PATH, замена %1 полным именем первого найденного файла. Если переменная среды не определена или поиск не обнаружил файлов, модификатор выдает пустую строку
%~dp1замена %1 именем диска и путем
%~nx1замена %1 именем файла и расширением
%~dp$PATH:1поиск в каталогах, перечисленных в переменной среды PATH, и замена %1 именем диска и путем к первому найденному файлу
%~ftza1замена %1 строкой, аналогичной результату работы программы dir


Примечания:

  • %1 и PATH в показанных выше примерах можно заменить на другие значения пакетных параметров.
  • Модификатор %* является уникальным, так как он представляет все аргументы, переданные пакетному файлу. Этот модификатор не используется в комбинации с модификатором %~. Конструкция %~ должна завершаться допустимым номером аргумента.
  • Нельзя манипулировать пакетными параметрами подобно переменным среды. Нельзя искать и заменять значения или контролировать подстроки. Но переменной среды можно назначить параметр, а потом уже ей манипулировать.


Использование фильтров

Фильтр команды используется с символом перенаправления канала команды (|) и является командой внутри команды, которая считывает ввод команды, преобразовывает ввод, а затем записывает выход. Команды-фильтры дают возможность сортировать, просматривать и отбирать часть выходной информации других команд.

Фильтры делят, переупорядочивают или выделяют отдельные части из проходящей через них информации. В приведенной ниже таблице перечислены команды-фильтры, доступные в Microsoft Windows XP:


Команда
Описание
moreОтображает содержимое файла или вывода команды в одном окне командной строки за раз
findПоиск указанных символов в файлах и выходе команды
sortСортировка файлов и выхода команды по алфавиту


Для направления данных из файла на вход фильтра используется символ «меньше» (<). Для направления на вход фильтра выхода другой команды используется канал (|).

Использование команды more:

Команда more выводит содержимое файла или выхода команды в одном окне командной строки. Например, чтобы отобразить содержимое файла List.txt в одном окне командной строки:
Код: Выделить всё
more < list. txt

Отображается одно окно командной строки со сведениями, а затем в нижней части окна командной строки отображается строка
-- More --
. Для перехода к следующему окну командной строки, используется любая клавиша на клавиатуре, кроме клавиши PAUSE. Для остановки просмотра применяется комбинация CTRL+C.

Команда more полезна при работе с командами, создающими выход более одного окна командной строки. Например, при выводе дерева каталогов жесткого диска. Если на диске содержится больше каталогов, чем может быть одновременно выведено в окне командной строки, можно использовать команду tree с каналом (|) и команду more.
Код: Выделить всё
tree c:\ | more


Использование команды find:

Команда find проводит поиск заданной строки или текста в файлах. Команда Cmd.exe отображает каждую строку, которая совпадает со строкой или текстом, указанным в окне командной строки. Команда find может быть использована как команда-фильтр и как обычная команда Microsoft Windows XP.

Чтобы использовать команду find в качестве команды-фильтра, необходимо включить символ «меньше» (<) и строку или текст, в котором требуется выполнить поиск. По умолчанию при поиске команда find учитывает регистр. Например, следующая команда будет искать строку «Pacific Rim» в файле Trade.txt:
Код: Выделить всё
find "Pacific Rim" < trade. txt

Выход не включает вхождение строки «pacific rim». Встречается вхождение строки «Pacific Rim» с прописными буквами.

Для сохранения результатов работы команды find (вместо отображения их в окне командной строки), надо ввести символ «больше» (>) и имя файла, в котором требуется хранить выход. Например, следующая команда ищет строку «Pacific Rim» в файле Trade.txt с сохранением результата в файле Nwtrade.txt:
Код: Выделить всё
find "Pacific Rim" < trade. txt > nwtrade. txt


Использование команды sort:

Команда sort выполняет сортировку по алфавиту текстового файла или выхода команды. Например, следующая команда сортирует содержимое файла List.txt и отображает результаты в окне командной строки:
Код: Выделить всё
sort < list. txt


В этом примере команда sort сортирует строки файла List.txt в алфавитном порядке и выводит результат на экран без изменения файла. Для сохранения результатов работы команды sort (вместо их отображения) введите символ «больше» (>) и имя файла. Например, следующую команду можно использовать для алфавитной сортировки строк файла List.txt и сохранения результатов в файле Alphlist.txt:
Код: Выделить всё
sort < list. txt > alphlist. txt


Для сортировки вывода команды следует ввести команду, затем символ канала (|) и команду sort (команда | sort). Например, следующая команда сортирует в алфавитном порядке строки, которые содержат слово «Jones» (вывод команды find):
Код: Выделить всё
find "Jones" maillst. txt | sort



Использование операторов перенаправления команд

Операторы перенаправления команд используются для изменения местоположений потоков ввода и вывода команд, заданных по умолчанию, на какие-либо другие. Местоположение потоков ввода и вывода называется дескриптор.

В следующей таблице описаны операторы перенаправления потоков ввода и вывода команд.


Оператор перенаправления
Описание
>Записывает данные на выходе команды вместо командной строки в файл или на устройство, например, на принтер
f<Читает поток входных данных команды из файла, а не с клавиатуры
>>Добавляет выходные данные команды в конец файла, не удаляя при этом существующей информации из файла
>&Считывает данные на выходе одного дескриптора как входные данные для другого дескриптора
<&Считывает входные данные одного дескриптора как выходные данные другого дескриптора
|Считывает выходные данные одной команды и записывает их на вход другой команды. Эта процедура известна под названием «канал»


По умолчанию, входные данные команды (дескриптор STDIN) отсылаются с клавиатуры интерпретатору команд Cmd.exe, далее Cmd.exe отправляет выходные данные команды (дескриптор STDOUT) в окно командной строки.

В следующей таблице представлены доступные дескрипторы:

Дескриптор
Числовой эквивалент дескриптора
Описание
STDIN0Ввод с клавиатуры
STDOUT1Вывод в окно командной строки
STDERR2Ошибка вывода в окно командной строки
UNDEFINED3-9Эти дескрипторы определяются индивидуально для каждой прикладной программы


Номера от 0 до 9 представляют первые 10 дескрипторов. Для запуска программы и перенаправления любого из 10 дескрипторов используется интерпретатор команд Cmd.exe. Для задания требуемого дескриптора перед оператором перенаправления введите его номер. Если дескриптор не определен, то по умолчанию оператором перенаправления ввода «<» будет ноль (0), а оператором перенаправления вывода «>» будет единица (1). После ввода оператора «<» или «>» необходимо указать, откуда читать и куда записывать данные. Можно задать имя файла или любой из существующих дескрипторов.

Для задания перенаправления в существующие дескрипторы используется амперсанд (&), затем номер требуемого дескриптора (например, &номер_дескриптора). Например, для перенаправления дескриптора 2 (STDERR) в дескриптор 1 (STDOUT):
Код: Выделить всё
1<&2


Дублирование дескрипторов:

Оператор перенаправления «&» дублирует выходные или входные данные с одного заданного дескриптора на другой заданный дескриптор. Например, для отправки выводных данных команды dir в файл File.txt и отправки ошибки вывода в файл File.txt:
Код: Выделить всё
dir>c:\file. txt 2>&1

При дублировании дескриптора происходит копирование всех его исходных характеристик. Например, если дескриптор доступен только для записи, то все его дубликаты будут доступны только для записи. Нельзя продублировать дескриптор с доступом только для чтения в дескриптор с доступом только для записи.

Перенаправление ввода команд (<):

Для перенаправления ввода команд с цифровой клавиатуры на файл или на устройство используйте оператор «<». Например, для ввода команды sort из файла List.txt:
Код: Выделить всё
sort<file. txt

Содержимое файла File.txt появится в командной строке в виде списка в алфавитном порядке.

Оператор «<» открывает заданное имя файла с доступом только для чтения. Поэтому с его помощью нельзя записывать в файл. Например, при запуске программы с оператором <&2 все попытки прочитать дескриптор 0 ни к чему не приведут, так как изначально он был открыт с доступом только для записи.

Примечание: Дескриптор 0 задан по умолчанию для оператора перенаправления ввода «<».

Перенаправление вывода команд (>):

Выходные данные практически всех команд высвечиваются в окне командной строки. Даже команды, выводящие данные на диск или принтер, выдают сообщения и запросы в окне командной строки.

Для перенаправления вывода команд из окна командной строки в файл или на устройство применяется оператор «>». Этот оператор используется с большинством команд. Например, для перенаправления вывода команды dir в файл Dirlist.txt:
Код: Выделить всё
dir>dirlist. txt

Если файл Dirlist.txt не существует, интерпретатор команд Cmd.exe создаст его. Если файл существует, Cmd.exe заменит информацию в файле на данные, полученные от команды dir.

Для запуска команды netsh routing dump и последующей отправки результатов ее работы в Route.cfg:
Код: Выделить всё
netsh routing dump>c:\route. cfg

Оператор «>» открывает заданный файл с доступом только для записи. Поэтому с помощью данного оператора файл прочитать нельзя. Например, при запуске программы с оператором перенаправления <&0 все попытки записать дескриптор 1 ни к чему не приведут, так как изначально дескриптор 0 был открыт с доступом только для чтения.

Примечание: Дескриптор 1 задан по умолчанию для оператора перенаправления вывода «>».

Использование оператора «<&» для перенаправления ввода и дублирования:

Для использования оператора перенаправления ввода необходимо, чтобы задаваемый файл уже существовал. Если файл для ввода существует, то интерпретатор команд Cmd.exe открывает его с доступом только для чтения и его содержимое отправляет в команду так, как если бы это был ввод с цифровой клавиатуры. При задании дескриптора интерпретатор команд Cmd.exe дублирует его в дескриптор, существующий в системе.
Например, для считывания файла File.txt на вход в дескриптор 0 (STDIN) введите:
Код: Выделить всё
<file. txt

Для открытия файла File.txt, сортировки его содержимого и последующей отправки в окно командной строки (STDOUT) введите:
Код: Выделить всё
sort<file. txt

Для того чтобы найти файл File.txt и перенаправить дескриптор 1 (STDOUT) и дескриптор 2 (STDERR) в Search.txt введите:
Код: Выделить всё
findfile file. txt>search. txt 2<&1

Для дублирования определенного пользователем дескриптора 3 в качестве входной информации для дескриптора 0 (STDIN):
Код: Выделить всё
<&3


Использование оператора «>&» для перенаправления ввода и дублирования:

При перенаправлении вывода в файл и задании существующего имени файла интерпретатор команд Cmd.exe открывает файл с доступом только для записи и переписывает его содержимое. Если дескриптор задан, интерпретатор команд Cmd.exe дублирует файл в существующий дескриптор.

Для дублирования определенного пользователем дескриптора 3 в дескриптор 1 введите:
Код: Выделить всё
>&3

Для перенаправления всех выходных данных, включая выходные данные дескриптора 2 (STDERR), команды ipconfig в дескриптор 1 (STDOUT) и последующего перенаправления выходных данных в Output.log введите:
Код: Выделить всё
ipconfig. exe>>output. log 2>&1


Использование оператора «>>» для добавления вывода:

Для добавления выходных данных команды в конец файла без потери хранящейся в нем информации используется двойной символ «больше» (>>). Например, следующая команда добавляет список каталогов, созданный командой dir, в файл Dirlist.txt:
Код: Выделить всё
dir>>dirlist. txt

Для добавления выходных данных команды netstat в конец файла Tcpinfo.txt введите:
Код: Выделить всё
netstat>>tcpinfo. txt


Использование оператора канала (|):

Оператор канала «вертикальная линия» (|) забирает выходные данные одной команды (по умолчанию STDOUT) и направляет их на вход другой команды (по умолчанию STDIN). Например, следующая команда сортирует каталог:
Код: Выделить всё
dir | sort

В данном примере обе команды запускаются одновременно, но команда sort приостанавливает работу до получения выходных данных команды dir. Команда sort использует выходные данные команды dir в качестве своих входных данных, а затем свои выходные данные отправляет в дескриптор 1 (STDOUT).

Комбинирование команд с операторами перенаправления:

Комбинируя команды-фильтры с другими командами и именами файлов, можно создавать команды на заказ. Например, для сохранения имен файлов, содержащих строку «LOG», используется следующая команда:
Код: Выделить всё
dir /b | find "LOG" > loglist. txt

Выход команды dir отсылается в команду-фильтр find. Имена файлов, содержащие строку «LOG», хранятся в файле Loglist.txt в виде списка (например, NetshConfig. log, Logdat. svd и Mylog. bat).

При использовании более одного фильтра в одной команде их необходимо отделять с помощью канала (|). Например, следующая команда ищет в каждом каталоге диска C файлы, в названии которых присутствует строка «Log», и выводит их постранично на экран:
Код: Выделить всё
dir c:\ /s /b | find "LOG" | more

Наличие канала (|) указывает Cmd.exe, что выход команды dir нужно отправить команде-фильтру find. Команда find выбирает только те имена файлов, в которых содержится строка «LOG». Команда more выводит на экран имена файлов, полученные командой find с паузой после заполнения каждого экрана.


Подстановка значений в переменные среды

Чтобы иметь возможность подставлять значения в переменную среды из командной строки или из сценариев, следует заключить имя соответствующей переменной в символы процентов (%имя_переменной%). Символы процентов указывают на то, что Cmd.exe должен обратиться к значениям переменных, а не делать посимвольное сравнение. После определения значения для имени переменной, имя переменной заключается в символы процентов. Cmd.exe проводит поиск всех вхождений имени переменной и заменяет его на определенное значение переменной. Например, требуется создать сценарий, содержащий различные значения (имена пользователей), и требуется определить соответствующее значение переменной среды USERNAME для каждого пользователя. Для этого следует написать сценарий с использованием переменной USERNAME, заключенной в кавычки. При выполнении сценария Cmd.exe заменит вхождения %USERNAME% соответствующими значениями, что избавит от необходимости делать это вручную для каждого пользователя. Подстановка значений не является рекурсивной. Cmd.exe проверяет переменные один раз.


Установка переменных среды

Используйте команду set для создания, удаления или отображения переменных среды. Команда set изменяет переменные только в среде текущей оболочки.

Чтобы отобразить переменную, в командной строке:
Код: Выделить всё
set имя_переменной

Чтобы добавить переменную, в командной строке:
Код: Выделить всё
set variablename=значение

Чтобы удалить переменную, в командной строке:
Код: Выделить всё
set имя_переменной=

Имеется возможность использовать большинство символов в качестве значений переменных, в том числе пробел. При использовании специальных символов, таких как <, >, &, или ^, перед ними следует помещать управляющий символ (^) или кавычки. При использовании кавычек они включаются в значение переменной, так как все символы, следующие после знака равенства принимаются за значение переменной.
Чтобы создать значение переменной new&name:
Код: Выделить всё
set varname=new^&name

Чтобы создать значение переменной "new&name":
Код: Выделить всё
set varname="new&name"

При вводе в командной строке set varname=new&name появляется следующее сообщение об ошибке:
name' is not recognized as an internal or external command, operable program or batch file


В именах переменных регистр символов не учитывается. Однако, команда set отображает значение переменной так, как оно было введено. Можно комбинировать символы нижнего и верхнего регистра в именах переменных, чтобы облегчить восприятие кода (например, ИмяПользователя).

Примечания:
  • Максимальный размер отдельной переменной среды составляет 8192 байта.
  • Максимальный общий размер всех переменных среды, включая имена переменных и знак равенства, составляет 65 536 Кбайт.

Статья Переменные в CMD, команда SET и арифметика

СообщениеДобавлено: 15 апр 2014 09:32, Вт
UncleFather
Следующая информация является копией статьи Статья Переменные в CMD, команда SET и арифметика. Уж больно хороша статья... Вдруг куда исчезнет... пусть уж у меня копия будет.

Задание переменных

Вручную:
Код: Выделить всё
set x=stroka
set /a y=55

Ввод с клавиатуры:
Код: Выделить всё
set /p x="BBeduTe cTpoky: "


Типы переменных

Тип строка:
Код: Выделить всё
set x=stroka

Ограничение 8184 символа.

Тип число:
Код: Выделить всё
set /a x=25*5

Ограничение от -2147483647 до 2147483647.

Использование переменных

Вывод значения переменных:
Код: Выделить всё
echo %x%


Существующие переменные

%RANDOM% - раскрывается в случайное десятичное число между 0 и 32767.(от 0 до (2^17)-1)
Код: Выделить всё
set /a random10=%random%/3277

Выводит случайное число от 0 до 9.
У меня это число по нелепой псевдослучайности цифру секунды
%CD% - раскрывается в строку текущей директории.
%DATE% - раскрывается в текущую дату, используя тот же формат команды DATE.
%TIME% - раскрывается в текущую дату, используя формат команды TIME.
%ERRORLEVEL% - раскрывается в текущее значение ERRORLEVEL.
Уровень ошибки, 0 - это нет ошибки, 1 - это есть ошибка, а другие это номера ошибки.

Чтобы получить полный список переменных и их значений введите команду:
Код: Выделить всё
SET


Операции со строковыми или численными переменными

Соединение 2-х строковых переменных:
Код: Выделить всё
set x=Gaz
set y=Prom
echo %x%%y%
(GazProm)

Вывод определенного(ых) символа(ов) из строки:
Символы номеруются начиная с 0!
Код: Выделить всё
set str=babywka

Вывод 1-ого символа:
Код: Выделить всё
echo %str:~0,1%
(b)

Вывод 3-х символов с конца строки:
Код: Выделить всё
echo %str:~-3%
(wka)

Вывод всей строки кроме 2-ух первых символов:
Код: Выделить всё
echo %str:~2%
(bywka)

Вывод всей строки кроме 2-ух последних символов:
Код: Выделить всё
echo %str:~0,-2%
(babyw)

Вывод 3-х символов начиная с 3:
Код: Выделить всё
echo %str:~2,3%
(byw)

Удаление подстроки из строки:
Код: Выделить всё
set str=babywka
echo %str:ba=%
(bywka)

Замена подстроки из строки на другую подстроку:
Код: Выделить всё
set str=babywka
echo %str:bab=xlop%
(xlopywka)

Удаление кавычек(") из строки:
Код: Выделить всё
set str2="qwerty"
echo %str2:"=%
(qwert)

В данном случае: если кавычки в начале и конце строки - можно использовать:
Код: Выделить всё
echo %str2:~1,-1%
(qwert)

Существуют 2 способа использовать переменную в переменной, например: вывод n-ого символа:
Первый способ с call set
Код: Выделить всё
call set x=%%str:~%n%,1%%
echo %x%

Второй способ с for и setlocal enabledelayedexpansion:
Код: Выделить всё
setlocal enabledelayedexpansion
for /l %%i in (%n%,1,%n%) do (set x=!str:~%%i,1!)
echo %x%

тут неважно что в for писать, главное:
Код: Выделить всё
set x=!str:~%n%,1!

писать в do
С циклами мы разберемся в следующей статье.
Но, пока уточню: если код второго способа использовать в пакетном файле (BAT-нике), то вместо %i используем %%i.

Операции с числовыми переменными

Увеличение на единицу:
Код: Выделить всё
set /a x+=1

Увеличение в 2 раза:
Код: Выделить всё
set /a x+=%x%

аналогично:
Код: Выделить всё
set /a x*=2

Возведение в квадрат:
Код: Выделить всё
set /a x*=%x%

Возведение в куб:
Код: Выделить всё
set /a x=%x%*%x%*%x%

Деление:
Деление в CMD является целочисленным!(то есть делится до целого числа)
Код: Выделить всё
set /a x=15
set /a y=4
set /a xy=%x%/%y%
(3)

Сложение:
Код: Выделить всё
set /a x=5
set /a y=-6
set /a xy=%x%+%y%
(5+(-6)=5-6=-1)

Вычитание:
Код: Выделить всё
set /a x=5
set /a y=-6
set /a xy=%x%-%y%
(5-(-6)=5+6=11)

Вычисление остатка:
Код: Выделить всё
set /a xy=%x% "%" %y%

Унарные операторы:
(Не знаю, как они называются)
Код: Выделить всё
set /a y="!"%x%

дает результат(%y%) 1, если переменная(%x%) равна 0, и 0 (%y%) в любых других случаях
Например:
Код: Выделить всё
set /a x=5
set /a y="!"%x%
(0)
set /a x=0
set /a y="!"%x%
(1)

Код: Выделить всё
set /a y="~"%x%

дает результат -1-%x% (%y%)
Например:
Код: Выделить всё
set /a x=5
set /a y="~"%x%
(-1-5=-(1+5)= -6)
set /a x=-3
set /a y="~"%x%
(-1-(-3)=-1+3=3-1= 2)

Отрицание:
Код: Выделить всё
set /a y="-"%x%

дает результат 0-%x% (%y%)
Например:
Код: Выделить всё
set /a x=5
set /a y="-"%x%
(-5)
set /a x=-3
set /a y="-"%x%
(3)


Двоичные операторы:

Код: Выделить всё
set x=3

(в двоичной системе счисления - 0011)
Код: Выделить всё
set y=5

(в двоичной системе счисления - 0101)

Побитовое И (AND) — это бинарная операция, действие которой эквивалентно применению логического И к каждой паре битов, которые стоят на одинаковых позициях в двоичных представлениях операндов.
Другими словами, если оба соответствующих бита операндов равны 1, результирующий двоичный разряд равен 1; если же хотя бы один бит из пары равен 0, результирующий двоичный разряд равен 0.
Код: Выделить всё
set /a xy=%x%"&"%y%

(1, в двоичной системе счисления - 0001)

Побитовое ИЛИ (OR) — это бинарная операция, действие которой эквивалентно применению логического ИЛИ к каждой паре битов, которые стоят на одинаковых позициях в двоичных представлениях операндов.
Другими словами, если оба соответствующих бита операндов равны 0, двоичный разряд результата равен 0; если же хотя бы один бит из пары равен 1, двоичный разряд результата равен 1.
Код: Выделить всё
set /a xy=%x%"|"%y%

(7, в двоичной системе счисления - 0111)

Побитовое исключающее ИЛИ (XOR) (или побитовое сложение по модулю два) — это бинарная операция, действие которой эквивалентно применению логического исключающего ИЛИ к каждой паре битов, которые стоят на одинаковых позициях в двоичных представлениях операндов.
Другими словами, если соответствующие биты операндов различны, то двоичный разряд результата равен 1; если же биты совпадают, то двоичный разряд результата равен 0.
Код: Выделить всё
set /a xy=%x%"^"%y%

(6, в двоичной системе счисления - 0110)
К битовым операциям также относят битовые сдвиги. При сдвиге значения битов копируются в соседние по направлению сдвига.
Различают сдвиг влево (в направлении от младшего бита к старшему) и вправо (в направлении от старшего бита к младшему).
При логическом сдвиге значение последнего бита по направлению сдвига теряется (копируясь в бит переноса), а первый приобретает нулевое значение.

Двоичный арифметический сдвиг:

Арифметический сдвиг аналогичен логическому, но значение слова считается знаковым числом, представленным в дополнительном коде.
Так, при правом сдвиге старший бит сохраняет свое значение. Левый арифметический сдвиг идентичен логическому.
Вправо:
Код: Выделить всё
set /a xy=%x%">>"1

(1, в двоичной системе счисления - 0011->0001)
Код: Выделить всё
set /a xy2=%y%">>"1

(2, в двоичной системе счисления - 0101->0010)
Код: Выделить всё
set /a n=13

(в двоичной системе счисления - 1101)
Код: Выделить всё
set /a xn=%n%">>"2

(3, в двоичной системе счисления - 1101->0011)
Код: Выделить всё
set /a my=-%y%">>"1

(-3, в двоичной системе счисления - 1011(-5)->1101(-3))
Влево:
Код: Выделить всё
set /a xy=%x%"<<"1

(6, в двоичной системе счисления - 0011->0110)
Код: Выделить всё
set /a xy2=%y%"<<"1

(10, в двоичной системе счисления - 0101->1010)
Код: Выделить всё
set /a xy3=%y%"<<"4

(80, в двоичной системе счисления - 0101->1010000)
Код: Выделить всё
set /a my=-%y%"<<"1

(-10, в двоичной системе счисления - 1011(-5)->10110(-10))
Максимальный размер отдельной переменной среды составляет 8192 байта.(у меня выходило только 8184, наверное это вместе с названием...)
Максимальный общий размер всех переменных среды, включая имена переменных и знак равенства, составляет 65 536 Кбайт.

И я забыл, про 8-ричную и 16-ричную систему счисления в CMD

Системы счисления

Числовые значения рассматриваются как десятичные, если перед ними не стоит префикс 0x для шестнадцатеричных чисел, и 0 для восьмеричных чисел. Например, числа 0x12, и 022 обозначают десятичное число 18.

Обратите внимание на запись восьмеричных числе: 08 и 09 не являются допустимыми числами, так как в восьмеричной системе исчисления цифры 8 и 9 не используются.

Восьмеричная система счисления:
Код: Выделить всё
set /a x=022

(Это 22 в восьмеричной системе счисления, и 18 в десятичной)
Можно производить все операции, также как и с десятеричными числами.
Но после задания значения переменной, значение хранится в десятичной системе счисления.
Например, сложение:
Код: Выделить всё
set /a xy=022+07

(Это 22+7=31 в восьмеричной системе счисления, и 31 в десятичной)
Шестнадцатеричная система счисления:
Код: Выделить всё
set /a x=0x3A

(Это 3A в восьмеричной системе счисления, и 58 в десятичной)
Вычитание:
Код: Выделить всё
set /a xy=0x3A-0x66

(Это 3A-66=-54 в восьмеричной системе счисления, и -44 в десятичной)

Сохранение в переменной вывода программы

К сожалению, передача вывода программ на вход команды set не работает:
Код: Выделить всё
echo 1|set /p AA=""
set AA

Поэтому можно воспользоваться временным сохранением в файл:
Код: Выделить всё
echo 1> 0.tmp
set /p AA="" <0.tmp
del 0.tmp
echo %AA%


Примеры использования

Узнать динамически генерируемое имя архива WinRar:
Код: Выделить всё
rar a -z%Comment% -p%p% "-ag yyyy-mm-dd[n]" %OutPath%\%arhivename%.%ext% @%FileList% >rar.log.tmp
for /f "tokens=2*" %%I in ('find /i "Creating archive" ^<rar.log.tmp') do @echo %%J >rarfilename.tmp
set /p rarfilename="" <rarfilename.tmp
del rarfilename.tmp

Узнать имя последнего изменённого файла в папке:
Код: Выделить всё
dir /b /a-d /o-d *.* >%temp%\0.tmp
set /p lastfile="" <%temp%\0.tmp
del %temp%\0.tmp
echo "%lastfile%"

Комментарий от Dragokas :
По сути, эта команда считывает в переменную первую строку файла:
Код: Выделить всё
set /p stroka=<file.txt


Урезание части строки, замена значения в переменной:
 
Код: Выделить всё
@Echo Off
:: Кодировка файла 'Кириллица DOS' (866)
Set var=123456789
Echo.
Echo             Запись     Значение
Echo.
Echo Переменная полностью       %%var%%     %var%
Echo.
Echo Первые три символа       %%var:~0,3%%   %var:~0,3%
Echo Последние три символа       %%var:~-3%%   %var:~-3%
Echo Три символа начиная с шестого     %%var:~5,3%%   %var:~5,3%
Echo Без первых трех символов     %%var:~3%%   %var:~3%
Echo Без последних трех символов     %%var:~0,-3%%   %var:~0,-3%
Echo Без первых двух и последних трех   %%var:~2,-3%%   %var:~2,-3%
Echo.
Echo Замена части переменной (45 на abc)   %%var:45=abc%%   %var:45=abc%
Echo Замена части переменной и символов
Echo до нее (23, и все что до этого, на xyz) %%var:*23=xyz%%   %var:*23=xyz%
Echo Удаление части переменной (567)     %%var:567=%%   %var:567=%
Pause>Nul


Вывод текста без переноса на новую строку:
 
Код: Выделить всё
@echo off
<nul set /p strTemp=Весь этот текст
<nul set /p strTemp=будет находиться
<nul set /p strTemp=на одной строке.
echo.
echo Новая строка

Ограничение - будет модифицирована переменная. Следует выбрать переменную, модификация которой не нарушит работу скрипта или использовать setlocal / endlocal.

Undocumented Dynamic variables (read only)
(Спасибо Charles Kludge​)
%__CD__% - текущий каталог, с бэкслэшем '\' в хвосте;
%=C:% - Текущий каталог на диске C:
%=D:% - Текущий каталог на диске D:,E:,F:...(буковку подставите), если к нему было обращение в текущем сеансе CMD.EXE
%=ExitCode% - Шестнадцатеричное значение кода возврата по EXIT /B
%=ExitCodeAscii% - Символьное (ASCII) представление кода возврата по EXIT /B, если он больше 32 (пробел).
 
Код: Выделить всё
@echo off
echo %__CD__%
echo %=C:%
set "decimal=%1"
cmd /c exit /b  %decimal%
echo ASCII(как символ) exitcode: %=ExitCodeAscii%
echo Hex exitcode: %=ExitCode%
pause


Полезные функции, Арифметика:
Получить уникальное имя файла во временной папке:
 
Код: Выделить всё
@echo off
Call :GetTemporaryName Name
Echo Temporary Name is %Name%
pause& exit

:GetTemporaryName %varName%
set sTempName=%temp%\temp%random%.tmp
if exist "%sTempName%" (goto :GetTemporaryName) else (set %1=%sTempName%)


Получить случайное число в пределах ...:
 
Мы знаем, что переменная %RANDOM% выводит значение в области от 0 до 32767,
а что если нам нужно диапазон уже, к примеру от -50 до 50? Вот решение:
Код: Выделить всё
@Echo Off
SetLocal
set min=-50
set max=50
set /a i=%random%%%(max-min+1)+min
Echo:%i%
pause>nul


Вычисление степени числа:
 Подпрограмма и пример использования:
Код: Выделить всё
@Echo Off
Setlocal EnableDelayedExpansion
Set /A num=3
::Вычисляем 3 в 4-й степени
Call :Stepping num 4
Echo %num%
pause
exit /B

:Stepping %1 - Переменная с числом %2 - Степень
set /A s=%2
if %s%==0 (Set /A %1=1& exit /b)
if %s%==1 exit /b
set step=%3
if not defined step set step=!%1!
set /A s-=1
set /A %1*=%step%
Call :Stepping %1 %s% %step%
exit /b


Деление с выведением дробной части:
 
Как известно в бат-файлах есть только операция целочисленного деления
и получения остатка от деления. Получить дробное число нельзя. Решил восполнить этот пробел:
Код: Выделить всё
::Деление с выводом дробной части на батниках - by Dragokas
@echo off
::Введите ограничение точности (знаков после точки)
::Не более 8 знаков !!! (ограничение арифметики от -2147483647 до 2147483647.)
Set /A Znak=8
::Введите делимое
Set /A n1=7
::Введите делитель
Set /A n2=6
::Разделитель целой и дробной части
Set Delim=.

Set /A nC=n1/n2
Set /A nO=%n1% %% %n2%
if %nO%==0 Goto :ret
Set /A nD=nO
For /L %%A in (1,1,%Znak%) do Set /A nD*=10
Set /A nD=nd/n2
:Trim0
Set /A rest=%nd% %% 10
if %rest%==0 (Set /A nd/=10& Goto :Trim0)
Set nd=%Delim%%nD%
:ret
Echo %nC%%nD%
pause>nul
Алгоритм получения дробной части:
Остаток от деления * (10^(знаков после запятой)) / делитель.
Потом убираются лишние концевые нули у дробной части.


Деление через строковую математику:
 
Отличие от встроенного в CMD деления: исходное число (делимое) может превышать границу для числового типа данных CMD
(актуально для Гигабайтов данных, представленных в виде байтов, для дальнейшего перевода в более удобо-читаемую единицу измерения).
Код: Выделить всё
:: Деление через строковую математику - by Dragokas
@echo off
SetLocal EnableDelayedExpansion
::Делимое
set Num1=16261316608
::Делитель
Set Num2=1024
::Макс. кол-во знаков после запятой в результате
Set MaxZ=2
set /a Num1_pos=-1
:AddNum1
set /a Num1_pos+=1
::если строка закончилась
if "!Num1:~%Num1_pos%,1!"=="" Goto AfterZiro
Set Num1_part=%Num1_part%!Num1:~%Num1_pos%,1!
if %Num1_part%==00 Set Num1_part=0
Call :TryDiv
Goto AddNum1
:AfterZiro
if %Num1_part%==0 goto Div_End
if %MaxZ% neq 0 Set ResultAll=%ResultAll%.
Set Zero_Marker=true
:AddZiro
Set /A MaxZ-=1
if %MaxZ% LSS 0 Goto Div_End
echo %Num1_part%
if %Num1_part%==0 goto Div_End
Set Num1_part=%Num1_part%0
Call :TryDiv
Goto AddZiro
:Div_End
echo %ResultAll%
pause
Goto :eof
:TryDiv
Set /a Result=Num1_part / Num2
echo %Num1_part%-%result%
if %Result% neq 0 (
  Set ResultAll=%ResultAll%%Result%
  Set /A Num1_part=Num1_part - Result * Num2
) else (if "%ResultAll%" neq "" if not Defined Zero_Marker Set ResultAll=%ResultAll%0)
Exit /B
Пример довольно прямолинеен, и не оптимизирован. Зато работает верно, надеюсь :D


Логические операции сравнения для чисел, превышающих арифметику CMD:
 Пример использования:
Код: Выделить всё
@echo off
SetLocal EnableExtensions
Call :Logica -2147483648 2147483648 LSS && echo false || echo true
echo errorlevel = %errorlevel%
<nul set /p x=Результат сравнения:
if "%errorlevel%"=="0" (echo false)
if "%errorlevel%"=="1" (echo true)
if "%errorlevel%"=="2" (echo error)
pause
goto :eof

Код: Выделить всё
:Logica
:: Логические операции сравнения для чисел, превышающих арифметику CMD - by Dragokas
:: Возвращает Errorlevel 1, если true, или 0, если false, 2, если неверно введен параметр
:: %1 - 1-е число
:: %2 - 2-е число
:: %3 - Логическая операция.
:: Допустимые операции:
:: LSS - меньше
:: lEQ - меньше или равно
:: GTR - больше
:: GEQ - больше или равно
  set operation=%~3
  set numb1=%~1
  set numb2=%~2
 ::Удаляем знаки +
  if "%numb1:~0,1%"=="+" set numb1=%numb1:~1%
  if "%numb2:~0,1%"=="+" set numb2=%numb2:~1%
 ::Проверка на равенство
  if "%numb1%"=="%numb2%" (
  if /i "%operation%"=="lEQ" exit /B 1
  if /i "%operation%"=="GEQ" exit /B 1
  if /i "%operation%"=="lSS" exit /B 0
  if /i "%operation%"=="GTR" exit /B 0
  )
  if /i "%operation%"=="lEQ" set operation=LSS
  if /i "%operation%"=="GEQ" set operation=GTR
 ::Если сравниваются отрицательные числа, нужно в конце переворачивать логику
  set inverse=
  if "%numb1:~0,1%"=="-" if "%numb2:~0,1%"=="-" set inverse=true
 ::Проверка на знак
  if "%numb1:~0,1%"=="-" if "%numb2:~0,1%" NEQ "-" (set mean=LSS& goto :ext_Logica)
  if "%numb2:~0,1%"=="-" if "%numb1:~0,1%" NEQ "-" (set mean=GTR& goto :ext_Logica)
 ::Удаляем знаки -
  if "%numb1:~0,1%"=="-" set numb1=%numb1:~1%
  if "%numb2:~0,1%"=="-" set numb2=%numb2:~1%
  :s_Logica
 ::Берем цифры по одному разряду справа
  if "%numb1%"=="" (set r1=) else (set r1=%numb1:~-1%)
  if "%numb2%"=="" (set r2=) else (set r2=%numb2:~-1%)
  if "%r1%"=="" if "%r2%"=="" goto ext_Logica
  if "%r1%"=="" set r1=0
  if "%r2%"=="" set r2=0
  if %r1% NEQ %r2% if %r1% GTR %r2% (set mean=GTR) else (set mean=LSS)
  if "%numb1%" neq "" set numb1=%numb1:~0,-1%
  if "%numb2%" neq "" set numb2=%numb2:~0,-1%
  goto s_Logica
  :ext_Logica
  if defined inverse if "%mean%"=="GTR" (set mean=LSS) else (set mean=GTR)
  if "%operation%"=="GTR" if "%mean%"=="GTR" (exit /B 1) else (exit /B 0)
  if "%operation%"=="LSS" if "%mean%"=="LSS" (exit /B 1) else (exit /B 0)
exit /B 2


Перевод чисел из десятеричной системы в любую (2-16):
 
Код: Выделить всё
@echo off
::Первый параметр - число в десятичное системе счисления.
::Второй параметр - основание выходной системы счисления (от 2 до 16)
setlocal enabledelayedexpansion
chcp 1251>nul
set dec=%~1
if not "%~2"=="" (set osn=%~2) else (set osn=2)
if !dec! LSS 0 (set /a dec=0 - !dec!&set mn=1)
set tempr=!dec!
set bin=
set H=set HEX.
!H!10=A&!H!11=B&!H!12=C&!H!13=D&!H!14=E&!H!15=F
if !osn! GTR 16 (echo.Слишком большое основание. Максимум 16&exit /b)
if !osn! LSS 2 (echo.Слишком маленькое основание. Минимум 2&exit /b)
:again
if !tempr! LSS 2 (goto :out)
set /a tbin=!tempr! %% !osn!
set /a tmchs=!tempr! - !tbin!
set /a tempr=!tmchs! / !osn!
if !tbin! GEQ 10 (set tbin=!HEX.%tbin%!)
set bin=!tbin!!bin!
goto :again
:out
if "!bin!"=="" (set bin=0)
if not !tempr!==0 (set bin=!tempr!!bin!)
if "!mn!"=="1" (set bin=-!bin!)
echo.!bin!
endlocal&exit /b


Полезные функции, Строки:
Проверка на содержание подстроки в строке:
 
1. Простой вариант - проверка на содержимое в строке заданной подстроки
Код: Выделить всё
set a=qwerty
if "%a:ty=%" neq "%a%"  echo "ty" present in string
Принцип работы: если подстрока присутствует в строке, она будет удалена и результат не будет равен исходной строке.
Не работает с пустыми строками.

2. Вариант, когда подстрока тоже в переменной
Код: Выделить всё
setlocal enabledelayedexpansion
set a=asdfgh
set b=df
if "!a:%b%=!" neq "!a!"  echo "%b%" present in string "%a%"


Изменение регистра всех букв в тексте:
 Пример использования и функция:
Код: Выделить всё
@echo off
Setlocal EnableDelayedExpansion
:: исходный текст
set Utext= Up case text--~@#*()_+-
Call :Case Utext U
:: текст после преобразования в U - верхний регистр
echo %Utext%

:: исходный текст
set Ltext=lAW CASE TEXT--~@#*()_+-
Call :Case Ltext L
:: текст после преобразования в L - нижний регистр
echo %Ltext%

pause
Goto :eof

:Case %1-var %2.option-L-or-U
if not Defined CaseA Call :FillSlovar
set word=!%~1!
if not Defined word Exit /B
set tempvar=
set /A n=-1
:newsymbol
set /A n+=1
set "symb=!word:~%n%,1!"
if "%symb%"=="" (Set "%~1=%tempvar%"& Exit /B)
if "!case%~2%symb%!"=="" (
  set "tempvar=%tempvar%%symb%"
) else (
  set "tempvar=%tempvar%!case%~2%symb%!"
)
goto :newsymbol

:FillSlovar
Set AlphabetL=abcdefghigklmnopqrstuvwxyz
Set AlphabetU=ABCDEFGHIJKLMNOPQRSTUVWXYZ
For /L %%C in (0,1,25) do (
  set caseU!AlphabetL:~%%C,1!=!AlphabetU:~%%C,1!
  set caseL!AlphabetU:~%%C,1!=!AlphabetL:~%%C,1!
)
Exit /B


Получение N-й строки из файла без использования (!) - DelayedExpansion:
 Пример для получения 5-й строки:
Код: Выделить всё
<test.txt (
  for /l %%i in (1 1 4) do set /p "="
  set /p "st="
)
for /f "tokens=1* delims==" %%i in ("%st%") do set "st=%%j"
echo %st%
pause


Получение символа BackSpace (0x08) в переменную:
 
Код: Выделить всё
for /F "tokens=1,2 delims=#" %%a in ('"prompt #$H# & echo on & for %%A in (1) do rem"') do set "DEL=%%a"

Перечень операторов (команд) командной строки

СообщениеДобавлено: 15 апр 2014 11:40, Вт
UncleFather
Перечень операторов (команд) командной строки

Источник - статья An A-Z Index of the Windows CMD command line

Оператор (команда)Краткое пояснение
A
ADDUSERSAdd or list users to/from a CSV file
ADmodcmdActive Directory Bulk Modify
ARPAddress Resolution Protocol
ASSOCChange file extension associations•
ASSOCIATOne step file association
ATSchedule a command to run at a specific time
ATTRIBChange file attributes
B
BCDBOOTCreate or repair a system partition
BCDEDITManage Boot Configuration Data
BITSADMINBackground Intelligent Transfer Service
BOOTCFGEdit Windows boot settings
BROWSTATGet domain, browser and PDC info
C
CACLSChange file permissions
CALLCall one batch program from another•
CERTREQRequest certificate from a certification authority
CERTUTILUtility for certification authority (CA) files and services
CDChange Directory - move to a specific Folder•
CHANGEChange Terminal Server Session properties
CHKDSKCheck Disk - check and repair disk problems
CHKNTFSCheck the NTFS file system
CHOICEAccept keyboard input to a batch file
CIPHEREncrypt or Decrypt files/folders
CleanMgrAutomated cleanup of Temp files, recycle bin
CLEARMEMClear memory leaks
CLIPCopy STDIN to the Windows clipboard
CLSClear the screen•
CLUSTERCreate or configure a cluster
CMDStart a new CMD shell
CMDKEYManage stored usernames/passwords
COLORChange colors of the CMD window•
COMPCompare the contents of two files or sets of files
COMPACTCompress files or folders on an NTFS partition
COMPRESSCompress one or more files
CON2PRTConnect or disconnect a Printer
CONVERTConvert a FAT drive to NTFS
COPYCopy one or more files to another location•
CSCcmdClient-side caching (Offline Files)
CSVDEImport or Export Active Directory data
D
DATEDisplay or set the date•
DEFRAGDefragment hard drive
DELDelete one or more files•
DELPROFDelete user profiles
DELTREEDelete a folder and all subfolders
DevConDevice Manager Command Line Utility
DIRDisplay a list of files and folders•
DIRUSEDisplay disk usage
DISKPARTDisk Administration
DISKSHADOWVolume Shadow Copy Service
DISKUSEShow the space used in folders
DOSKEYEdit command line, recall commands, and create macros
DriverQueryDisplay installed device drivers
DSACLsActive Directory ACLs
DSAddAdd items to active directory (user group computer)
DSGetView items in active directory (user group computer)
DSQuerySearch for items in active directory (user group computer)
DSModModify items in active directory (user group computer)
DSMoveMove an Active directory Object
DSRMRemove items from Active Directory
E
ECHODisplay message on screen•
ENDLOCALEnd localisation of environment changes in a batch file•
ERASEDelete one or more files•
EVENTCREATEAdd a message to the Windows event log
EXITQuit the current script/routine and set an errorlevel•
EXPANDUncompress CAB files
EXTRACTUncompress CAB files
F
FCCompare two files
FINDSearch for a text string in a file
FINDSTRSearch for strings in files
FOR /FLoop command: against a set of files•
FOR /FLoop command: against the results of another command•
FORLoop command: all options Files, Directory, List•
FORFILESBatch process multiple files
FORMATFormat a disk
FREEDISKCheck free disk space
FSUTILFile and Volume utilities
FTPFile Transfer Protocol
FTYPEFile extension file type associations•
G
GETMACDisplay the Media Access Control (MAC) address
GOTODirect a batch program to jump to a labelled line•
GPRESULTDisplay Resultant Set of Policy information
GPUPDATEUpdate Group Policy settings
H
HELPOnline Help
HOSTNAMEDisplay the host name of the computer
I
iCACLSChange file and folder permissions
IFConditionally perform a command•
IFMEMBERIs the current user a member of a group
IPCONFIGConfigure IP
INUSEReplace files that are in use by the OS
L
LABELEdit a disk label
LOGEVENTWrite text to the event viewer
LOGMANManage Performance Monitor
LOGOFFLog a user off
LOGTIMELog the date and time in a file
M
MAKECABCreate .CAB files
MAPISENDSend email from the command line
MBSAcliBaseline Security Analyzer
MEMDisplay memory usage
MDCreate new folders•
MKLINKCreate a symbolic link (linkd) •
MODEConfigure a system device
MOREDisplay output, one screen at a time
MOUNTVOLManage a volume mount point
MOVEMove files from one folder to another•
MOVEUSERMove a user from one domain to another
MSGSend a message
MSIEXECMicrosoft Windows Installer
MSINFO32System Information
MSTSCTerminal Server Connection (Remote Desktop Protocol)
N
NETManage network resources
NETDOMDomain Manager
NETSHConfigure Network Interfaces, Windows Firewall & Remote access
NETSVCCommand-line Service Controller
NBTSTATDisplay networking statistics (NetBIOS over TCP/IP)
NETSTATDisplay networking statistics (TCP/IP)
NOWDisplay the current Date and Time
NSLOOKUPName server lookup
NTBACKUPBackup folders to tape
NTDSUtilActive Directory Domain Services management
NTRIGHTSEdit user account rights
O
OPENFILESQuery or display open files
P
PATHDisplay or set a search path for executable files•
PATHPINGTrace route plus network latency and packet loss
PAUSESuspend processing of a batch file and display a message•
PERMSShow permissions for a user
PERFMONPerformance Monitor
PINGTest a network connection
POPDReturn to a previous directory saved by PUSHD•
PORTQRYDisplay the status of ports and services
POWERCFGConfigure power settings
PRINTPrint a text file
PRINTBRMPrint queue Backup/Recovery
PRNCNFGDisplay, configure or rename a printer
PRNMNGRAdd, delete, list printers set the default printer
PROMPTChange the command prompt•
PsExecExecute process remotely
PsFileShow files opened remotely
PsGetSidDisplay the SID of a computer or a user
PsInfoList information about a system
PsKillKill processes by name or process ID
PsListList detailed information about processes
PsLoggedOnWho's logged on (locally or via resource sharing)
PsLogListEvent log records
PsPasswdChange account password
PsPingMeasure network performance
PsServiceView and control services
PsShutdownShutdown or reboot a computer
PsSuspendSuspend processes
PUSHDSave and then change the current directory•
Q
QGREPSearch file(s) for lines that match a given pattern
Query Process / QPROCESSDisplay processes
Query Session / QWinstaDisplay all sessions (TS/Remote Desktop)
Query TermServer /QAppSrvList all servers (TS/Remote Desktop)
Query User / QUSERDisplay user sessions (TS/Remote Desktop)
R
RASDIALManage RAS connections
RASPHONEManage RAS connections
RECOVERRecover a damaged file from a defective disk
REGRegistry: Read, Set, Export, Delete keys and values
REGEDITImport or export registry settings
REGSVR32Register or unregister a DLL
REGINIChange Registry Permissions
REMRecord comments (remarks) in a batch file•
RENRename a file or files•
REPLACEReplace or update one file with another
Reset SessionDelete a Remote Desktop Session
RDDelete folder(s)•
RMTSHAREShare a folder or a printer
ROBOCOPYRobust File and Folder Copy
ROUTEManipulate network routing tables
RUNStart | RUN commands
RUNASExecute a program under a different user account
RUNDLL32Run a DLL command (add/remove print connections)
S
SCService Control
SCHTASKSSchedule a command to run at a specific time
SCLISTDisplay Services
SETDisplay, set, or remove session environment variables•
SETLOCALControl the visibility of environment variables•
SETXSet environment variables
SFCSystem File Checker
SHAREList or edit a file share or print share
ShellRunAsRun a command under a different user account
SHIFTShift the position of batch file parameters•
SHORTCUTCreate a windows shortcut (.LNK file)
SHOWGRPSList the groups a user has joined
SHOWMBRSList the Users who are members of a group
SHUTDOWNShutdown the computer
SLEEPWait for x seconds
SLMGRSoftware Licensing Management (Vista/2008)
SOONSchedule a command to run in the near future
SORTSort input
STARTStart a program, command or batch file•
SUBINACLEdit file and folder Permissions, Ownership and Domain
SUBSTAssociate a path with a drive letter
SYSTEMINFOList system configuration
T
TAKEOWNTake ownership of a file
TASKLISTList running applications and services
TASKKILLEnd a running process
TELNETCommunicate with another host using the TELNET protocol
TIMEDisplay or set the system time•
TIMEOUTDelay processing of a batch file
TITLESet the window title for a CMD.EXE session•
TLISTTask list with full path
TOUCHChange file timestamps
TRACERTTrace route to a remote host
TREEGraphical display of folder structure
TSDISCONDisconnect a Remote Desktop Session
TSKILLEnd a running process
TSSHUTDNRemotely shut down or reboot a terminal server
TYPEDisplay the contents of a text file•
TypePerfWrite performance data to a log file
V
VERDisplay version information•
VERIFYVerify that files have been saved•
VOLDisplay a disk label•
W
WAITFORWait for or send a signal
WEVTUTILClear event logs, enable/disable/query logs
WHERELocate and display files in a directory tree
WHOAMIOutput the current UserName and domain
WINDIFFCompare the contents of two files or sets of files
WINMSDPWindows system report
WINRMWindows Remote Management
WINRSWindows Remote Shell
WMICWMI Commands
WUAUCLTWindows Update
X
XCACLSChange file and folder permissions
XCOPYCopy files and folders
::Comment / Remark•

Дополнительные материалы

СообщениеДобавлено: 10 сен 2014 17:29, Ср
UncleFather
Отличная статья Командные файлы Windows.

Содержание: