Google Chrome, Mozilla Firefox. Отключение обновлений

Задача:

Необходимо полностью отключить обновление (возможность обновления) в браузерах Google Chrome и Mozilla Firefox.

Решение:

Для Google Chrome, только для случая когда ПК является членом домена Active Directory:

Создаем в реестре по адресу HKEY_LOCAL_MACHINE\SOFTWARE\Policies\Google\Update два параметра Update{8A69D345-D564-463C-AFF1-A69D9E530F96} и UpdateDefault типа REG_DWORD и устанавливаем им значение 0.

Либо то же самое делаем командами:

Код: Выделить всё

reg add HKLM\SOFTWARE\Policies\Google\Update /f /v Update{8A69D345-D564-463C-AFF1-A69D9E530F96} /t Reg_DWORD /d 0
reg add HKLM\SOFTWARE\Policies\Google\Update /f /v UpdateDefault /t Reg_DWORD /d 0

Для того, чтоб вернуть возможность обновлений, выполняем команды:

Код: Выделить всё

reg delete HKLM\SOFTWARE\Policies\Google\Update /f /v Update{8A69D345-D564-463C-AFF1-A69D9E530F96}
reg delete HKLM\SOFTWARE\Policies\Google\Update /f /v UpdateDefault

Для Google Chrome, вне зависимости от членства ПК в домене AD - универсальный способ:

Переименовываем исполняемый файл GoogleUpdate.exe (поскольку расположение исполняемого файла заранее неизвестно, просто перебираем все возможные варианты):

Код: Выделить всё

ren "%LocalAppData%\Google\Update\GoogleUpdate.exe" GoogleUpdate.exe.bak
ren "%ProgramData%\Google\Update\GoogleUpdate.exe" GoogleUpdate.exe.bak
ren "%ProgramFiles%\Google\Update\GoogleUpdate.exe" GoogleUpdate.exe.bak
ren "%ProgramFiles(x86)%\Google\Update\GoogleUpdate.exe" GoogleUpdate.exe.bak

Для того, чтоб вернуть возможность обновлений, выполняем обратное переименование:

Код: Выделить всё

ren "%LocalAppData%\Google\Update\GoogleUpdate.exe.bak" GoogleUpdate.exe
ren "%ProgramData%\Google\Update\GoogleUpdate.exe.bak" GoogleUpdate.exe
ren "%ProgramFiles%\Google\Update\GoogleUpdate.exe.bak" GoogleUpdate.exe
ren "%ProgramFiles(x86)%\Google\Update\GoogleUpdate.exe.bak" GoogleUpdate.exe

Для Mozilla Firefox:

Создаем в реестре по адресу HKEY_LOCAL_MACHINE\SOFTWARE\Policies\Mozilla\Firefox параметр DisableAppUpdate типа REG_DWORD и устанавливаем ему значение 1.

Либо то же самое делаем командой:

Код: Выделить всё

reg add HKLM\SOFTWARE\Policies\Mozilla\Firefox /f /v DisableAppUpdate /t Reg_DWORD /d 1

Для восстановления возможности обновлений:

Код: Выделить всё

reg delete HKLM\SOFTWARE\Policies\Mozilla\Firefox /f /v DisableAppUpdate

Дополнение 1:

Google Chrome. Отключаем сохранение паролей

Дополнение 2:

Полное отключение обновлений MS Windows

Дополнение 3:

Скрипт для отключения обновлений ОС MS Windows, браузеров Google Chrome и Mozilla Firefox. Скрипт предоставляет возможность удаления всех сохраненных паролей Google Chrome. Текущие настройки «Центра обновлений Windows» и пароли Google Chrome сохраняются в резервные копии, которые можно восстановить при необходимости:

скрипт

Код: Выделить всё

@Echo off
REM Устанавливаем кодовую страницу для корректного отображения кириллицы
>nul chcp 866
REM >nul chcp 1251
REM Создаём константу, содержащую текущую дату и время
SET VTIME=%date%-%time:~0,-3%
REM Удаляем символы двоеточия, а символы пробела заменяем нулями
SET VTIME=%VTIME::=.%
SET VTIME=%VTIME: =0%
REM Останавливаем службу "Центр обновления Windows"
sc stop wuauserv
REM Отключаем запуск службы "Центр обновления Windows"
sc config wuauserv start=disabled
REM На некоторых версиях ОС Windows требуется пробел после знака равенства
sc config wuauserv start= disabled
REM Настриваем параметры "Центр обновления Windows" на отключение получения и установки обновлений
REM Сохраняем текущие настройки службы "Центр обновления Windows" в файл
MD %SystemDrive%\Distr\Reg
reg export HKLM\SOFTWARE\Policies\Microsoft\Windows\WindowsUpdate C:\Distr\Reg\AU_Enabled.%VTIME%.reg
REM Очищаем ранее настроенные параметры "Центр обновления Windows" 
reg delete HKLM\SOFTWARE\Policies\Microsoft\Windows\WindowsUpdate /f
REM Прописываем адрес альтернативного корпоративного центра обновлений
reg add HKLM\SOFTWARE\Policies\Microsoft\Windows\WindowsUpdate /f /v WUServer /t Reg_SZ /d "http://myserver.local:8530"
reg add HKLM\SOFTWARE\Policies\Microsoft\Windows\WindowsUpdate /f /v WUStatusServer /t Reg_SZ /d "http://myserver.local:8530"
REM Настриваем прочие параметры "Центр обновления Windows" на отключение получения и установки обновлений
reg add HKLM\SOFTWARE\Policies\Microsoft\Windows\WindowsUpdate /f /v DisableOSUpgrade /t Reg_DWORD /d 1
reg add HKLM\SOFTWARE\Policies\Microsoft\Windows\WindowsUpdate\AU /f /v NoAutoUpdate /t Reg_DWORD /d 1
REM reg add HKLM\SOFTWARE\Policies\Microsoft\Windows\WindowsUpdate\AU /f /v AUOptions /t Reg_DWORD /d 1
reg add HKLM\SOFTWARE\Policies\Microsoft\Windows\WindowsUpdate\AU /f /v AutoInstallMinorUpdates /t Reg_DWORD /d 0
reg add HKLM\SOFTWARE\Policies\Microsoft\Windows\WindowsUpdate\AU /f /v IncludeRecommendedUpdates /t Reg_DWORD /d 0
reg add HKLM\SOFTWARE\Policies\Microsoft\Windows\WindowsUpdate\AU /f /v AUPowerManagement /t Reg_DWORD /d 0
reg add HKLM\SOFTWARE\Policies\Microsoft\Windows\WindowsUpdate\AU /f /v UseWUServer /t Reg_DWORD /d 1
REM ******************************************************
REM Отключаем обновление для Firefox
reg add HKLM\SOFTWARE\Policies\Mozilla\Firefox /f /v DisableAppUpdate /t Reg_DWORD /d 1
REM Отключаем обновление для Chrome если ПК член домена AD
reg add HKLM\SOFTWARE\Policies\Google\Update /f /v Update{8A69D345-D564-463C-AFF1-A69D9E530F96} /t Reg_DWORD /d 0
reg add HKLM\SOFTWARE\Policies\Google\Update /f /v UpdateDefault /t Reg_DWORD /d 0
REM Отключаем обновление для Chrome для любого ПК
ren "%LocalAppData%\Google\Update\GoogleUpdate.exe" GoogleUpdate.exe.bak
ren "%ProgramData%\Google\Update\GoogleUpdate.exe" GoogleUpdate.exe.bak
ren "%ProgramFiles%\Google\Update\GoogleUpdate.exe" GoogleUpdate.exe.bak
ren "%ProgramFiles(x86)%\Google\Update\GoogleUpdate.exe" GoogleUpdate.exe.bak
REM Отключаем возможность сохранения паролей для Chrome
reg add HKCU\Software\Policies\Google\Chrome /f /v PasswordManagerEnabled /t Reg_DWORD /d 0
REM Очищаем сохраненные пароли Google Chrome
REM Ожидаем выбора пользователя
set choice=
Set /p choice="“¤ «Ёвм б®еа ҐлҐ ў Google Chrome Ї а®«Ё? (Y/N)"
REM if not defined choice goto menu
REM Перебираем все варианты нажатия кнопки "Y"
if "%choice%"=="L" (goto DelPass)
if "%choice%"=="l" (goto DelPass)
if "%choice%"=="Y" (goto DelPass)
if "%choice%"=="y" (goto DelPass)
if "%choice%"=="„" (goto DelPass)
if "%choice%"=="¤" (goto DelPass)
if "%choice%"=="Ќ" (goto DelPass)
if "%choice%"=="" (goto DelPass)
REM Если нет совпадений, считаем что очистка старых паролей из браузера не требуется и завершаем скрипт
Exit
:DelPass
REM Завершаем работу браузера Google Chrome
taskkill.exe /F /T /IM chrome.exe
REM Ожидаем несколько секунд
Echo.*********************** ‚бс Ё¤Ґв Ї®-Ї« г! Ћ¦Ё¤ Ґ¬ § ўҐаиҐЁп... ***********************
ping -n 20 localhost>nul
REM Определяем версию операционной системы
ver | find /i "5.1" >Nul
REM Переименовываем файлы, содержащие хранилище паролей
if %errorlevel% == 0 (
REM Если ОС Windows XP
ren "%USERPROFILE%\Local Settings\Application Data\Google\Chrome\User Data\Default\Login Data" "Login Data.%VTIME%.bak"
ren "%USERPROFILE%\Local Settings\Application Data\Google\Chrome\User Data\Default\Login Data-journal" "Login Data-journal.%VTIME%.bak"
) ELSE (
REM Если ОС не Windows XP
ren "%localappdata%\Google\Chrome\User Data\Default\Login Data" "Login Data.%VTIME%.bak"
ren "%localappdata%\Google\Chrome\User Data\Default\Login Data-journal" "Login Data-journal.%VTIME%.bak"
)

Скрипт для включения возможности обновлений ОС MS Windows, браузеров Google Chrome и Mozilla Firefox. Скрипт восстанавливает ранее сохраненные настройки «Центра обновлений Windows» и пароли Google Chrome:

скрипт

Код: Выделить всё

@Echo off
REM Устанавливаем кодовую страницу для корректного отображения кириллицы
>nul chcp 866
REM >nul chcp 1251
REM Создаём константу, содержащую текущую дату и время
SET VTIME=%date%-%time:~0,-3%
REM Удаляем символы двоеточия, а символы пробела заменяем нулями
SET VTIME=%VTIME::=.%
SET VTIME=%VTIME: =0%
REM Включаем запуск службы "Центр обновления Windows"
sc config wuauserv start=auto
REM На некоторых версиях ОС Windows требуется пробел после знака равенства
sc config wuauserv start= auto
REM Запускаем службу "Центр обновления Windows"
sc start wuauserv
REM Настриваем параметры "Центр обновления Windows" на включение получения и установки обновлений
REM Сохраняем текущие настройки службы "Центр обновления Windows" в файл
MD %SystemDrive%\Distr\Reg
reg export HKLM\SOFTWARE\Policies\Microsoft\Windows\WindowsUpdate C:\Distr\Reg\AU_Disabled.%VTIME%.reg
REM Очищаем ранее настроенные параметры "Центр обновления Windows"
reg delete HKLM\SOFTWARE\Policies\Microsoft\Windows\WindowsUpdate /f
REM Находим самую раннюю сохраненную версию файла с параметрами "Центр обновления Windows"
set "regfilename="
REM Выводим список файлов (без папок) по маске, в хронологической последовательности
for /f "delims=#" %%i in ('dir /b /T:C /A:-D /O:D "%SystemDrive%\Distr\Reg\AU_Enabled.*-??.??.??.reg"') do (
REM Берем первый файл
set "regfilename=%%~i"
REM Выходим из цикла
goto:presentRegFiles
)
:presentRegFiles
REM Если сохраненных файлов реестра не найдено, пропускаем этап их восстановления
if not defined regfilename goto:noRegFiles
reg import "%SystemDrive%\Distr\Reg\%regfilename%"
:noRegFiles
REM Включаем обновление для Firefox
reg delete HKLM\SOFTWARE\Policies\Mozilla\Firefox /f /v DisableAppUpdate
REM Включаем обновление для Chrome если ПК член домена AD
reg delete HKLM\SOFTWARE\Policies\Google\Update /f /v Update{8A69D345-D564-463C-AFF1-A69D9E530F96}
reg delete HKLM\SOFTWARE\Policies\Google\Update /f /v UpdateDefault
REM Включаем обновление для Chrome для любого ПК
ren "%LocalAppData%\Google\Update\GoogleUpdate.exe.bak" GoogleUpdate.exe
ren "%ProgramData%\Google\Update\GoogleUpdate.exe.bak" GoogleUpdate.exe
ren "%ProgramFiles%\Google\Update\GoogleUpdate.exe.bak" GoogleUpdate.exe
ren "%ProgramFiles(x86)%\Google\Update\GoogleUpdate.exe.bak" GoogleUpdate.exe
REM Включаем возможность сохранения паролей для Chrome
reg delete HKCU\Software\Policies\Google\Chrome /f /v PasswordManagerEnabled
REM Находим самую раннюю сохраненную версию файла-хранилища паролей Google Chrome
set "filename="
REM Выводим список файлов (без папок) по маске, в хронологической последовательности
for /f "delims=#" %%i in ('dir /b /T:C /A:-D /O:D "%localappdata%\Google\Chrome\User Data\Default\Login Data.*-??.??.??.bak"') do (
REM Берем первый файл
set "filename=%%~i"
REM Выходим из цикла
goto:presentBakFiles
)
:presentBakFiles
REM Если сохраненных копий файлов-хранилищ не найдено, пропускаем этап их восстановления
if not defined filename goto:noBakFiles
REM Завершаем работу браузера Google Chrome
taskkill.exe /F /T /IM chrome.exe
REM Ожидаем несколько секунд
Echo.*********************** ‚бс Ё¤Ґв Ї®-Ї« г! Ћ¦Ё¤ Ґ¬ § ўҐаиҐЁп... ***********************
ping -n 20 localhost>nul
REM Определяем версию операционной системы
ver | find /i "5.1" >Nul
REM Объявляем переменную, содержащую путь до пользовательских настроек Google Chrome
if %errorlevel% == 0 (
REM Если ОС Windows XP
SET Path2Settings=%USERPROFILE%\Local Settings\Application Data\Google\Chrome\User Data\Default) ELSE (
REM Если ОС не Windows XP
SET Path2Settings=%localappdata%\Google\Chrome\User Data\Default)
echo %Path2Settings%Login Data
echo %Path2Settings%Login Data-journal
REM На всякий случай сохраняем текущие хранилища паролей
ren "%Path2Settings%Login Data" "Login Data.%VTIME%.sav"
ren "%Path2Settings%Login Data-journal" "Login Data-journal.%VTIME%.sav"
REM Восстанавливаем самые ранние копии хранилища паролей
ren "%Path2Settings%%filename%" "Login Data"
SET filename=%filename:Login Data=Login Data-journal%
ren "%Path2Settings%%filename%" "Login Data-journal"
:noBakFiles
EXIT

Архив со скриптами отключения (DisableUpdates) и включения (EnableUpdates) обновлений и этими же скриптами, запакованными (с помощью архиватора WinRAR) в exe-файлы, запускающиеся с запросом административных прав можно скачать здесь:

Disable-Enable_Updates.rar: (311.21 КБ) 56 скачиваний