Google Chrome. Отключаем сохранение паролей

Задача:

Необходимо отключить возможность сохранения паролей в браузере Google Chrome из командной строки (из скрипта).

Решение:

Отключение возможности сохранения паролей в браузере Google Chrome доступно в настройках самого браузера, однако нас интересует автоматизация этого процесса, что возможно только при запуске файла сценария (скрипта).

В реестре по адресу HKEY_CURRENT_USER\Software\Policies\Google\Chrome создаем параметр PasswordManagerEnabled типа REG_DWORD и устанавливаем ему значение 0.

Либо все то же самое выполняем командой:

Код: Выделить всё

reg add HKCU\Software\Policies\Google\Chrome /f /v PasswordManagerEnabled /t Reg_DWORD /d 0

Либо пользуемся групповыми политиками для Google Chrome: Конфигурация пользователя -> Политики -> Административные шаблоны -> Классические административные шаблоны -> Google -> Google Chrome -> Диспетчер паролей -> Устанавливаем политику «Включить диспетчер паролей» в состояние Отключено.

Для включения возможности сохранения паролей выполняем:

Код: Выделить всё

reg delete HKCU\Software\Policies\Google\Chrome /f /v PasswordManagerEnabled

Дополнение 1:

Отключение возможности сохранения паролей, не запрещает пользоваться паролями, которые были сохранены в Google Chrome до применения этой политики. Поэтому, если нужно отключить использование и старых (уже сохраненных) паролей, необходимо очистить хранилище паролей текущего пользователя. Сделать это можно либо из интерфейса браузера, либо, переименовав два файла Login Data и Login Data-journal в папке профиля пользователя браузера (требуется, чтобы браузер на время переименования был закрыт):
для Windows XP:

Код: Выделить всё

ren "%USERPROFILE%\Local Settings\Application Data\Google\Chrome\User Data\Default\Login Data" "Login Data.bak"
ren "%USERPROFILE%\Local Settings\Application Data\Google\Chrome\User Data\Default\Login Data-journal" "Login Data-journal.bak"

для Windows Vista и выше:

Код: Выделить всё

ren "%localappdata%\Google\Chrome\User Data\Default\Login Data" "Login Data.bak" 
ren "%localappdata%\Google\Chrome\User Data\Default\Login Data-journal" "Login Data-journal.bak"

Дополнение 2:

Приведу пример скрипта (сценария), который отключает возможность обновления браузеров Mozilla Firefox и Google Chrome, затем отключает возможность сохранения паролей в Google Chrome, после чего предлагает очистить хранилище паролей текущего пользователя в браузере Google Chrome:

Скрипт

Код: Выделить всё

@Echo off
REM Создаём константу, содержащую текущую дату и время
SET VTIME=%date%-%time:~0,-3%
REM Удаляем символы двоеточия, а символы пробела заменяем нулями
SET VTIME=%VTIME::=.%
SET VTIME=%VTIME: =0%
REM Отключаем обновление для Firefox
reg add HKLM\SOFTWARE\Policies\Mozilla\Firefox /f /v DisableAppUpdate /t Reg_DWORD /d 1
REM Отключаем обновление для Chrome если ПК член домена AD
reg add HKLM\SOFTWARE\Policies\Google\Update /f /v Update{8A69D345-D564-463C-AFF1-A69D9E530F96} /t Reg_DWORD /d 0
reg add HKLM\SOFTWARE\Policies\Google\Update /f /v UpdateDefault /t Reg_DWORD /d 0
REM Отключаем обновление для Chrome для любого ПК
ren "%LocalAppData%\Google\Update\GoogleUpdate.exe" GoogleUpdate.exe.bak
ren "%ProgramData%\Google\Update\GoogleUpdate.exe" GoogleUpdate.exe.bak
ren "%ProgramFiles%\Google\Update\GoogleUpdate.exe" GoogleUpdate.exe.bak
ren "%ProgramFiles(x86)%\Google\Update\GoogleUpdate.exe" GoogleUpdate.exe.bak
REM Отключаем возможность сохранения паролей для Chrome
reg add HKCU\Software\Policies\Google\Chrome /f /v PasswordManagerEnabled /t Reg_DWORD /d 0
REM Устанавливаем кодовую страницу для корректного отображения кириллицы
>nul chcp 866
REM >nul chcp 1251
REM Ожидаем выбора пользователя
set choice=
Set /p choice="“¤ «Ёвм б®еа ҐлҐ ў Google Chrome Ї а®«Ё? (Y/N)"
REM if not defined choice goto menu
REM Перебираем все варианты нажатия кнопки "Y"
if "%choice%"=="L" (goto DelPass)
if "%choice%"=="l" (goto DelPass)
if "%choice%"=="Y" (goto DelPass)
if "%choice%"=="y" (goto DelPass)
if "%choice%"=="„" (goto DelPass)
if "%choice%"=="¤" (goto DelPass)
if "%choice%"=="Ќ" (goto DelPass)
if "%choice%"=="" (goto DelPass)
REM Если нет совпадений, считаем что очистка старых паролей из браузера не требуется и завершаем скрипт
Exit
:DelPass
REM Завершаем работу браузера Google Chrome
taskkill.exe /F /T /IM chrome.exe
REM Ожидаем несколько секунд
Echo.*********************** ‚бс Ё¤Ґв Ї®-Ї« г! Ћ¦Ё¤ Ґ¬ § ўҐаиҐЁп... ***********************
ping -n 20 localhost>nul
REM Определяем версию операционной системы
ver | find /i "5.1" >Nul
REM Переименовываем файлы, содержащие хранилище паролей
if %errorlevel% == 0 (
REM Если ОС Windows XP
ren "%USERPROFILE%\Local Settings\Application Data\Google\Chrome\User Data\Default\Login Data" "Login Data.%VTIME%.bak"
ren "%USERPROFILE%\Local Settings\Application Data\Google\Chrome\User Data\Default\Login Data-journal" "Login Data-journal.%VTIME%.bak"
) ELSE (
REM Если ОС не Windows XP
ren "%localappdata%\Google\Chrome\User Data\Default\Login Data" "Login Data.%VTIME%.bak"
ren "%localappdata%\Google\Chrome\User Data\Default\Login Data-journal" "Login Data-journal.%VTIME%.bak"
)

И скрипт, выполняющий обратные действия - включает возможность обновлений браузеров Google Chrome и Mozilla Firefox и восстанавливает ранее сохраненные настройки «Центра обновлений Windows» и пароли Google Chrome:

скрипт

Код: Выделить всё

@Echo off
REM Создаём константу, содержащую текущую дату и время
SET VTIME=%date%-%time:~0,-3%
REM Удаляем символы двоеточия, а символы пробела заменяем нулями
SET VTIME=%VTIME::=.%
SET VTIME=%VTIME: =0%
REM Включаем обновление для Firefox
reg delete HKLM\SOFTWARE\Policies\Mozilla\Firefox /f /v DisableAppUpdate
REM Включаем обновление для Chrome если ПК член домена AD
reg delete HKLM\SOFTWARE\Policies\Google\Update /f /v Update{8A69D345-D564-463C-AFF1-A69D9E530F96}
reg delete HKLM\SOFTWARE\Policies\Google\Update /f /v UpdateDefault
REM Включаем обновление для Chrome для любого ПК
ren "%LocalAppData%\Google\Update\GoogleUpdate.exe.bak" GoogleUpdate.exe
ren "%ProgramData%\Google\Update\GoogleUpdate.exe.bak" GoogleUpdate.exe
ren "%ProgramFiles%\Google\Update\GoogleUpdate.exe.bak" GoogleUpdate.exe
ren "%ProgramFiles(x86)%\Google\Update\GoogleUpdate.exe.bak" GoogleUpdate.exe
REM Включаем возможность сохранения паролей для Chrome
reg delete HKCU\Software\Policies\Google\Chrome /f /v PasswordManagerEnabled
REM Находим самую раннюю сохраненную версию файла-хранилища паролей Google Chrome
set "filename="
REM Выводим список файлов (без папок) по маске, в хронологической последовательности
for /f "delims=#" %%i in ('dir /b /T:C /A:-D /O:D "%localappdata%\Google\Chrome\User Data\Default\Login Data.*-??.??.??.bak"') do (
REM Берем первый файл
set "filename=%%~i"
REM Выходим из цикла
goto:presentBakFiles
)
:presentBakFiles
REM Если сохраненных копий файлов-хранилищ не найдено, пропускаем этап их восстановления
if not defined filename goto:noBakFiles
REM Завершаем работу браузера Google Chrome
taskkill.exe /F /T /IM chrome.exe
REM Ожидаем несколько секунд
Echo.*********************** ‚бс Ё¤Ґв Ї®-Ї« г! Ћ¦Ё¤ Ґ¬ § ўҐаиҐЁп... ***********************
ping -n 20 localhost>nul
REM Определяем версию операционной системы
ver | find /i "5.1" >Nul
REM Объявляем переменную, содержащую путь до пользовательских настроек Google Chrome
if %errorlevel% == 0 (
REM Если ОС Windows XP
SET Path2Settings=%USERPROFILE%\Local Settings\Application Data\Google\Chrome\User Data\Default) ELSE (
REM Если ОС не Windows XP
SET Path2Settings=%localappdata%\Google\Chrome\User Data\Default)
echo %Path2Settings%Login Data
echo %Path2Settings%Login Data-journal
REM На всякий случай сохраняем текущие хранилища паролей
ren "%Path2Settings%Login Data" "Login Data.%VTIME%.sav"
ren "%Path2Settings%Login Data-journal" "Login Data-journal.%VTIME%.sav"
REM Восстанавливаем самые ранние копии хранилища паролей
ren "%Path2Settings%%filename%" "Login Data"
SET filename=%filename:Login Data=Login Data-journal%
ren "%Path2Settings%%filename%" "Login Data-journal"
:noBakFiles
EXIT

Архив со скриптами отключения (DisableBrowserUpdates) и включения (EnableBrowserUpdates) обновлений и этими же скриптами, запакованными (с помощью архиватора WinRAR) в exe-файлы, запускающиеся с запросом административных прав можно скачать здесь:

Disable-Enable_Browser_Updates.rar: (309.42 КБ) 29 скачиваний

Дополнение 3:

Google Chrome, Mozilla Firefox. Отключение обновлений

Дополнение 4:

Полное отключение обновлений MS Windows