Полное отключение обновлений MS Windows

Все об администрировании рабочих станций Windows 95/98/NT/2000/XP/7/8. То, чего не найдешь в бескрайних просторах Интернета. Решения тех проблем, которые не решаются типовыми ответами, которые можно получить в техподдержке Майкрософта - а именно: переустановить продукт или купить какой-ть другой лицензионный диск.


Модератор: UncleFather

Аватара пользователя
UncleFather
Site Admin
Сообщения: 1490
Зарегистрирован: 17 авг 2004 16:20, Вт
Контактная информация:

Полное отключение обновлений MS Windows

Сообщение UncleFather »

Задача:

Необходимо отключить обновления операционной системы MS Windows (вне зависимости от версии)


Решение:

Выполняем следующий скрипт от имени Администратора:

Скрипт

Код: Выделить всё

@Echo off
REM Устанавливаем кодовую страницу для корректного отображения кириллицы
>nul chcp 866
REM >nul chcp 1251
REM Останавливаем службу "Центр обновления Windows"
sc stop wuauserv
REM Отключаем запуск службы "Центр обновления Windows"
sc config wuauserv start=disabled
REM На некоторых версиях ОС Windows требуется пробел после знака равенства
sc config wuauserv start= disabled
REM Настриваем параметры "Центр обновления Windows" на отключение получения и установки обновлений
REM Сохраняем текущие настройки службы "Центр обновления Windows" в файл
MD %SystemDrive%\Distr\Reg
reg export HKLM\SOFTWARE\Policies\Microsoft\Windows\WindowsUpdate C:\Distr\Reg\AU_Enabled.reg
REM Очищаем ранее настроенные параметры "Центр обновления Windows" 
reg delete HKLM\SOFTWARE\Policies\Microsoft\Windows\WindowsUpdate /f
REM Прописываем адрес альтернативного корпоративного центра обновлений
reg add HKLM\SOFTWARE\Policies\Microsoft\Windows\WindowsUpdate /f /v WUServer /t Reg_SZ /d "http://myserver.local:8530"
reg add HKLM\SOFTWARE\Policies\Microsoft\Windows\WindowsUpdate /f /v WUStatusServer /t Reg_SZ /d "http://myserver.local:8530"
REM Настриваем прочие параметры "Центр обновления Windows" на отключение получения и установки обновлений
reg add HKLM\SOFTWARE\Policies\Microsoft\Windows\WindowsUpdate /f /v DisableOSUpgrade /t Reg_DWORD /d 1
reg add HKLM\SOFTWARE\Policies\Microsoft\Windows\WindowsUpdate\AU /f /v NoAutoUpdate /t Reg_DWORD /d 1
REM reg add HKLM\SOFTWARE\Policies\Microsoft\Windows\WindowsUpdate\AU /f /v AUOptions /t Reg_DWORD /d 1
reg add HKLM\SOFTWARE\Policies\Microsoft\Windows\WindowsUpdate\AU /f /v AutoInstallMinorUpdates /t Reg_DWORD /d 0
reg add HKLM\SOFTWARE\Policies\Microsoft\Windows\WindowsUpdate\AU /f /v IncludeRecommendedUpdates /t Reg_DWORD /d 0
reg add HKLM\SOFTWARE\Policies\Microsoft\Windows\WindowsUpdate\AU /f /v AUPowerManagement /t Reg_DWORD /d 0
reg add HKLM\SOFTWARE\Policies\Microsoft\Windows\WindowsUpdate\AU /f /v UseWUServer /t Reg_DWORD /d 1

Здесь останавливается и отключается служба «Центр обновления Windows», затем сохраняются текущие настройки обновлений, после чего настройки очищаются до дефолтного состояния и поверх прописываются параметры, запрещающие операционной системе обновляться из центра обновлений Microsoft. В скрипт можно прописать адрес своего сервера WSUS.

Этот скрипт можно запаковать в exe-файл, запускающийся с запросом административных прав с помощью архиватора WinRAR.

Все эти настройки можно также выполнить вручную, запретив запуск и остановив службу «Центр обновления Windows» и создав/изменив значения ключей реестра, прописанных в этом скрипте.

Либо можно настроить групповые политики на запрет запуска службы «Центр обновления Windows» и прописать значения соответствующие изменяемым скриптом параметрам в Конфигурация компьютера -> Административные шаблоны -> Компоненты Windows -> Центр обновления Windows:

  • DisableOSUpgrade - Turn off the upgrade to the latest version of the Windows through Windows Update

  • WUServer, WUStatusServer и UseWUServer - Указать размещение службы обновлений Microsoft в интрасети

  • NoAutoUpdate - Настройка автоматического обновления

  • AutoInstallMinorUpdates - Разрешить немедленную установку автоматических обновлений

  • IncludeRecommendedUpdates - Включить рекомендуемые обновления через автоматическое обновление

  • AUPowerManagement - Разрешить управлению электропитанием центра обновлений Windows выводить компьютер из спящего режима для установки запланированных обновлений

Скрипт и исполняемый exe-файл в архиве можно скачать здесь:

DisableUpdates.rar
(153.35 КБ) 19 скачиваний

При желании, можно предварительно сохранить свои старые настройки обновлений командой:

Код: Выделить всё

reg export HKLM\SOFTWARE\Policies\Microsoft\Windows\WindowsUpdate %temp%\AU_Enabled.reg

Чтобы восстановить их, выполняем команду:

Код: Выделить всё

reg import %temp%\AU_Enabled.reg

Чтобы сбросить все настройки обновлений к значениям по умолчанию, выполняем:

Код: Выделить всё

reg delete HKLM\SOFTWARE\Policies\Microsoft\Windows\WindowsUpdate /f

Чтобы восстановить автоматический запуск службы обновлений выполняем:

Код: Выделить всё

sc config wuauserv start=auto
sc start wuauserv

Дополнение 1:

Скрипт, отключающий обновления ОС MS Windows и сохраняющий текущие настройки «Центр обновлений Windows» будет выглядеть так:

скрипт

Код: Выделить всё

@Echo off
REM Устанавливаем кодовую страницу для корректного отображения кириллицы
>nul chcp 866
REM >nul chcp 1251
REM Создаём константу, содержащую текущую дату и время
SET VTIME=%date%-%time:~0,-3%
REM Удаляем символы двоеточия, а символы пробела заменяем нулями
SET VTIME=%VTIME::=.%
SET VTIME=%VTIME: =0%
REM Останавливаем службу "Центр обновления Windows"
sc stop wuauserv
REM Отключаем запуск службы "Центр обновления Windows"
sc config wuauserv start=disabled
REM На некоторых версиях ОС Windows требуется пробел после знака равенства
sc config wuauserv start= disabled
REM Настраиваем параметры "Центр обновления Windows" на отключение получения и установки обновлений
REM Сохраняем текущие настройки службы "Центр обновления Windows" в файл
MD %SystemDrive%\Distr\Reg
reg export HKLM\SOFTWARE\Policies\Microsoft\Windows\WindowsUpdate C:\Distr\Reg\AU_Enabled.%VTIME%.reg
REM Очищаем ранее настроенные параметры "Центр обновления Windows" 
reg delete HKLM\SOFTWARE\Policies\Microsoft\Windows\WindowsUpdate /f
REM Прописываем адрес альтернативного корпоративного центра обновлений
reg add HKLM\SOFTWARE\Policies\Microsoft\Windows\WindowsUpdate /f /v WUServer /t Reg_SZ /d "http://myserver.local:8530"
reg add HKLM\SOFTWARE\Policies\Microsoft\Windows\WindowsUpdate /f /v WUStatusServer /t Reg_SZ /d "http://myserver.local:8530"
REM Настраиваем прочие параметры "Центр обновления Windows" на отключение получения и установки обновлений
reg add HKLM\SOFTWARE\Policies\Microsoft\Windows\WindowsUpdate /f /v DisableOSUpgrade /t Reg_DWORD /d 1
reg add HKLM\SOFTWARE\Policies\Microsoft\Windows\WindowsUpdate\AU /f /v NoAutoUpdate /t Reg_DWORD /d 1
REM reg add HKLM\SOFTWARE\Policies\Microsoft\Windows\WindowsUpdate\AU /f /v AUOptions /t Reg_DWORD /d 1
reg add HKLM\SOFTWARE\Policies\Microsoft\Windows\WindowsUpdate\AU /f /v AutoInstallMinorUpdates /t Reg_DWORD /d 0
reg add HKLM\SOFTWARE\Policies\Microsoft\Windows\WindowsUpdate\AU /f /v IncludeRecommendedUpdates /t Reg_DWORD /d 0
reg add HKLM\SOFTWARE\Policies\Microsoft\Windows\WindowsUpdate\AU /f /v AUPowerManagement /t Reg_DWORD /d 0
reg add HKLM\SOFTWARE\Policies\Microsoft\Windows\WindowsUpdate\AU /f /v UseWUServer /t Reg_DWORD /d 1

Скрипт, включающий возможность обновления ОС MS Windows, и, восстанавливающий сохраненные ранее значения параметров:

скрипт

Код: Выделить всё

@Echo off
REM Устанавливаем кодовую страницу для корректного отображения кириллицы
>nul chcp 866
REM >nul chcp 1251
REM Создаём константу, содержащую текущую дату и время
SET VTIME=%date%-%time:~0,-3%
REM Удаляем символы двоеточия, а символы пробела заменяем нулями
SET VTIME=%VTIME::=.%
SET VTIME=%VTIME: =0%
REM Включаем запуск службы "Центр обновления Windows"
sc config wuauserv start=auto
REM На некоторых версиях ОС Windows требуется пробел после знака равенства
sc config wuauserv start= auto
REM Запускаем службу "Центр обновления Windows"
sc start wuauserv
REM Настриваем параметры "Центр обновления Windows" на включение получения и установки обновлений
REM Сохраняем текущие настройки службы "Центр обновления Windows" в файл
MD %SystemDrive%\Distr\Reg
reg export HKLM\SOFTWARE\Policies\Microsoft\Windows\WindowsUpdate C:\Distr\Reg\AU_Disabled.%VTIME%.reg
REM Очищаем ранее настроенные параметры "Центр обновления Windows"
reg delete HKLM\SOFTWARE\Policies\Microsoft\Windows\WindowsUpdate /f
REM Находим самую раннюю сохраненную версию файла с параметрами "Центр обновления Windows"
set "regfilename="
REM Выводим список файлов (без папок) по маске, в хронологической последовательности
for /f "delims=#" %%i in ('dir /b /T:C /A:-D /O:D "%SystemDrive%\Distr\Reg\AU_Enabled.*-??.??.??.reg"') do (
REM Берем первый файл
set "regfilename=%%~i"
REM Выходим из цикла
goto:presentRegFiles
)
:presentRegFiles
REM Если сохраненных файлов реестра не найдено, пропускаем этап их восстановления
if not defined regfilename goto:noRegFiles
reg import "%SystemDrive%\Distr\Reg\%regfilename%"
:noRegFiles
Exit

Архив со скриптами отключения (DisableWindowsUpdates) и включения (EnableWindowsUpdates) возможности обновлений и этими же скриптами, запакованными (с помощью архиватора WinRAR) в exe-файлы, запускающиеся с запросом административных прав можно скачать здесь:

Disable-Enable_Windows_Updates.rar
(307.74 КБ) 17 скачиваний

Дополнение 2:

Google Chrome. Отключаем сохранение паролей


Дополнение 3:

Google Chrome, Mozilla Firefox. Отключение обновлений


Дополнение 4:

Скрипт для отключения/включения обновлений ОС MS Windows, браузеров Google Chrome и Mozilla Firefox. Скрипт предоставляет возможность удаления/восстановления паролей Google Chrome. Текущие настройки «Центра обновлений Windows» и пароли Google Chrome так же сохраняются и восстанавливаются:
Архив со скриптом

Описание работы и листинг скриптов смотрим в теме Google Chrome, Mozilla Firefox. Отключение обновлений. Дополнение 3.


Alexander A. Manaeff©

Понравилась статья? Будем крайне признательны за репосты в соцсетях! Материально поддержать проект можно здесь

Мои странички:
ВКонтакте
Одноклассники
Youtube
Facebook
Instagram

Изображение
Изображение
Изображение
Изображение